如何在syntastic vim插件中添加c ++ 11支持？

Question

我在c ++ 11项目中使用了syntastic。当我在vim中编辑，并保存（：w）时，syntastic插件会在每个初始化列表{}和每个循环上给出错误，这些循环显然是缺少的c ++ 11特性。

我使用病原体安装了合成物。

以下是我在初始化列表和每个循环上获得的错误的两个示例（c ++ 11编译正常）：

Answer 1

事实证明，Syntirus的C ++ linter（语法检查器）有很多可以在你的.vimrc上设置的选项（不幸的是，我希望它是项目特定的，比如.clang_complete解决方案）。

要启用c ++ 11标准并使用带clang的libc ++库（这是我的项目正在使用的），我将以下行添加到〜/ .vimrc

let g:syntastic_cpp_compiler = 'clang++'
let g:syntastic_cpp_compiler_options = ' -std=c++11 -stdlib=libc++'

现在效果很好。

Answer 2

我遇到了同样的问题而我坚持分别处理c ++ 98和c ++ 11 。以下是我的解决方案：

在 bundle / syntastic / syntax_checkers / cpp11 / 下创建名为 gcc.vim 的文件并将其复制到其中：

"============================================================================
"File:        cpp11.vim
"Description: Syntax checking plugin for syntastic.vim
"Maintainer:  Gregor Uhlenheuer <kongo2002 at gmail dot com>
"License:     This program is free software. It comes without any warranty,
"             to the extent permitted by applicable law. You can redistribute
"             it and/or modify it under the terms of the Do What The Fuck You
"             Want To Public License, Version 2, as published by Sam Hocevar.
"             See http://sam.zoy.org/wtfpl/COPYING for more details.
"
"============================================================================

if exists('g:loaded_syntastic_cpp11_gcc_checker')
    finish
endif
let g:loaded_syntastic_cpp11_gcc_checker = 1

if !exists('g:syntastic_cpp11_compiler')
    let g:syntastic_cpp11_compiler = executable('g++') ? 'g++' : 'clang++'
endif

if !exists('g:syntastic_cpp11_compiler_options')
    let g:syntastic_cpp11_compiler_options = '-std=c++11'
endif

let s:save_cpo = &cpo
set cpo&vim

function! SyntaxCheckers_cpp11_gcc_IsAvailable() dict
    return executable(expand(g:syntastic_cpp11_compiler))
endfunction

function! SyntaxCheckers_cpp11_gcc_GetLocList() dict
    return syntastic#c#GetLocList('cpp11', 'gcc', {
        \ 'errorformat':
        \     '%-G%f:%s:,' .
        \     '%f:%l:%c: %trror: %m,' .
        \     '%f:%l:%c: %tarning: %m,' .
        \     '%f:%l:%c: %m,'.
        \     '%f:%l: %trror: %m,'.
        \     '%f:%l: %tarning: %m,'.
        \     '%f:%l: %m',
        \ 'main_flags': '-x c++ -fsyntax-only',
        \ 'header_flags': '-x c++',
        \ 'header_names': '\m\.\(h\|hpp\|hh\)$' })
endfunction

call g:SyntasticRegistry.CreateAndRegisterChecker({
    \ 'filetype': 'cpp11',
    \ 'name': 'gcc' })

let &cpo = s:save_cpo
unlet s:save_cpo

" vim: set et sts=4 sw=4:

这将使gcc检查器可用（想要其他检查器吗？你可以做我自己做的类似事情）对于带有＆amp; filetype ==＆＃39; cpp11＆＃39;的文件在vim。如何在vim中将文件自动识别为cpp11文件类型？只需在〜/ .vim / ftdetect / 下创建名为 ext_detect.vim 的文件，其中包含以下内容：

au bufnewfile,bufread *.cpp11 set ft=cpp11
au bufnewfile,bufread *.cppx set ft=cpp11

通过这种方式，您可以将* .cpp文件分别作为c ++ 98标准和* .cpp11或* .cppx处理为c ++ 11标准，不仅可以进行语法检查，还可以处理语法高亮（如果需要） cpp11语法高亮支持，this vim plugin将是有用的，虽然不完美）。

Answer 3

它具有项目特定选项，例如.clang_complete解决方案

您可以设置文件路径g：syntastic_cpp_config_file和g：syntastic_c_config_file。对于C ++，默认值为.syntastic_cpp_config。将文件放在项目的根目录和其中的编译器选项中（每行一个）

for details

Answer 4

如果您在使用Syntastic之外使用YouCompleteMe，则需要更改.ycm_extra_conf.py文件。巧妙地将'-Wc ++ 98-compat'改为'-Wnoc ++ 98-compat'。

我自己不必更改Syntastic设置，虽然这可能是因为我使用的是compile_commands.json文件。

via here

Answer 5

如果您使用YouCompleteMe，也许您应该更改＆＃39; .ycm_extra_conf.py＆＃39;。只更改标志:(文件路径〜/ .vim / bundle / YouCompleteMe / third_party / ycmd / cpp / ycm / .ycm_extra_conf .py）;

 flags = [
 '-std=c++11',
 '-O0',  
 '-Werror', 
 '-Weverything', 
 '-Wno-documentation', 
 '-Wno-deprecated-declarations', 
 '-Wno-disabled-macro-expansion', 
 '-Wno-float-equal', 
 '-Wno-c++98-compat', 
 '-Wno-c++98-compat-pedantic', 
 '-Wno-global-constructors', 
 '-Wno-exit-time-destructors', 
 '-Wno-missing-prototypes', 
 '-Wno-padded', 
 '-Wno-old-style-cast',
 '-Wno-weak-vtables',
 '-x', 
 'c++', 
 '-I', 
 '.', 
 '-isystem', 
 '/usr/include/',
 ]