Question

我有一个非常强大的技巧，我正在尝试保存我输入的每个命令：

function zshaddhistory() {
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
    ]] && return 1
    # do not do anything on common commands

    # do the needful
    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

    # rest is supposedly "default" zshaddhistory() (except it ain't)
    print -Sr ${COMMAND_STR}
    fc -p
}

让这项工作正常进行是一件非常困难的事情（例如使用print -S所以它不会搞砸!$ et.al.），但它现在主要适合我。

但是，我注意到现在我正在构建一个python脚本，在彩色列中打印出已保存的命令，因此会有一些轻微的不一致。

举例说明：

% echo "\\"
\

现在~/.zsh_enhanced_history现在包含：

/home/slu/util; echo "\"; /dev/pts/20@1376064693.136746657

因此，它将echo "\\"（产生输出\）保存为echo "\"（这不是格式正确的命令）。

同样，命令echo "\n"使用文字换行保存，因此它将占用历史文件中的两行。实际上这种行为导致我最初找到它，因为我的python正则表达式会为命令产生尽可能多的失败解析，因为该命令中有新行。

我尝试更改它，因此我将printf "%q" "$COMMAND_STR"的输出保存为$COMMAND_STR，这似乎解决了换行符，甚至可能是反斜杠，但它使它转义空格和双引号，所以这也是错的。

常规~/.zsh_history文件不会遇到此问题，它包含的命令与输入的完全相同。

所以我zshaddhistory的某个地方，我没有做正确的转换。也许我需要防止出现额外的shell-string-eval。

需要zsh专家的帮助!!

Answer 1

来自zsh邮件列表的

This example使用print。将它与你的功能结合起来就可以了：

zshaddhistory () {
    # Print to the default history file with the newline stripped. 
    print -sr -- "${1%%$'\n'}"

    # Ignore common commands. 
    COMMAND_STR=${1%%$'\n'}
    [[ ( -z $COMMAND_STR ) || ( $COMMAND_STR =~ hist(ory)? ) || \
        ( $COMMAND_STR =~ ^l(s\|l\|a)?$ ) || \
        ( $COMMAND_STR =~ ^(d\|gd\|git\ diff\|glp\|gg)$ ) \
        ]] && return 1


    # Switch history contexts
    fc -p ~/.zsh_history_detail
    # Push the current line into the current history context with newline stripped and user / time appended. 
    print -sr -- "${1%%$'\n'} ### ${PWD} $(date '+%Y-%m-%d %R')"
    return 1
}

这似乎可以做你想要的。我已使用echo "\\"和echo "\n"进行了测试：

charizard% cat ~/.zsh_history_detail                               
cat: /Users/simont/.zsh_history_detail: No such file or directory
charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
charizard% cat "\n"      # This was an oopsie                      
cat: \n: No such file or directory
charizard% echo "\n"                                               


charizard% echo "\\"                                               
\
charizard% cat ~/.zsh_history_detail                               
: 1376117319:0;echo "\\" ### /Users/simont 2013-08-10 16:18
: 1376117334:0;cat "\n" ### /Users/simont 2013-08-10 16:18
: 1376117339:0;echo "\n" ### /Users/simont 2013-08-10 16:18
: 1376117343:0;echo "\\" ### /Users/simont 2013-08-10 16:19

我不知道你的意思：

但它使它转义空格和双引号，所以它也是错误的

所以我无法测试。

Answer 2

我找到了问题的根源，通过阅读zsh手册页部分比我之前更加谨慎，这一点很明显。

在print下：

          -r     Ignore the escape conventions of echo.

所以，我必须对我的zshrc进行的唯一更改（我的~/.zshrc符号链接到此zshrc文件）是：

diff --git a/zshrc b/zshrc
index 5e72133..af97c35 100644
--- a/zshrc
+++ b/zshrc
@@ -68,7 +68,7 @@ function zshaddhistory() {
     # do not do anything on common commands

     # do the needful
-    echo "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history
+    print -r "$PWD; $COMMAND_STR; $TTY@$HOST@$(date +%s.%N)" >> ~/.zsh_enhanced_history

     # rest is "default" zshaddhistory()
     print -Sr ${COMMAND_STR}

正确的zsh shell命令擒纵机构

2 个答案: