Question

我想为webservice编写一个包装器方法，该服务接受2个强制参数和3个可选参数。

要有一个较短的例子，我想让以下代码正常工作

def myMethod(pParm1='1', pParm2='2') {
    println "${pParm1}${pParm2}"
}

myMethod();
myMethod('a')
myMethod(pParm2:'a') // doesn't work as expected
myMethod('b','c')

输出结果为：

12
a2
[pParm2:a]2
a2
bc

我想要实现的是提供一个参数并获得1a作为结果。这是否可能（以最懒惰的方式）？

Answer 1

不能按原样完成......代码

def myMethod(pParm1='1', pParm2='2'){
    println "${pParm1}${pParm2}"
}

基本上使groovy创建以下方法：

Object myMethod( pParm1, pParm2 ) {
    println "$pParm1$pParm2"
}

Object myMethod( pParm1 ) {
    this.myMethod( pParm1, '2' )
}

Object myMethod() {
    this.myMethod( '1', '2' )
}

一种替代方案是将可选的Map作为第一个参数：

def myMethod( Map map = [:], String mandatory1, String mandatory2 ){
    println "${mandatory1} ${mandatory2} ${map.parm1 ?: '1'} ${map.parm2 ?: '2'}"
}

myMethod( 'a', 'b' )                // prints 'a b 1 2'
myMethod( 'a', 'b', parm1:'value' ) // prints 'a b value 2'
myMethod( 'a', 'b', parm2:'2nd')    // prints 'a b 1 2nd'

显然，记录这一点让其他人知道神奇的map中的内容以及默认值是留给读者的; - ）

Answer 2

您可以使用默认值的参数。

def someMethod(def mandatory,def optional=null){}

如果参数“optional”不存在，则变为null。

Answer 3

只是简化了蒂姆的答案。正如已经建议的那样，执行此操作的常规方法是使用地图，但接下来将必需参数也放入地图中。看起来像这样：

def someMethod(def args) {
    println "MANDATORY1=${args.mandatory1}"
    println "MANDATORY2=${args.mandatory2}"
    println "OPTIONAL1=${args?.optional1}"
    println "OPTIONAL2=${args?.optional2}"
}

someMethod mandatory1:1, mandatory2:2, optional1:3

输出：

MANDATORY1=1
MANDATORY2=2
OPTIONAL1=3
OPTIONAL2=null

这看起来更好，它的优点是您可以根据需要更改参数的顺序。

带有可选参数的Groovy方法

3 个答案: