Question

我花了大量时间在几十个excel文件中创建相同的图表（所有文件都包含相同格式的数据），并且相信必须有一种更有效的方式来完成我刚刚完成的工作。

为简化起见，请考虑50个具有相同格式数据的Excel文档。 是否存在自动方法：

创建简单的折线图
添加轴标签，图表标签，删除水平网格线
包括趋势线/ R ^ 2值
将新工作簿保存到某个位置，文件名后附加“_graphed”

这可能是Excel VBA可以用于什么吗？

Answer 1

对于这类问题，我首先要记录您手动进入personal macro workbook的步骤的宏。然后，您可以查看Excel生成的代码，您可能会发现您不需要进行太多更改就可以将其用作通用过程。

经过测试，如果您想进一步提高自动化程度，可以编写一个小程序来遍历目录中的所有Excel文件，并在打开时为每个文件调用图表过程。我可以挖出我编写的代码，如果它会有所帮助。

<强>更新 Here是一个线程，我提供了一些代码来循环遍历包含一些给定文本的所有文件（在这个例子中是“.pdf”，但可以很容易地“.xls”来覆盖xlsx，xlsm等）

此示例还会将找到的文件列表打印到工作表中。这是测试结果的良好开端，但一旦可以，您将需要替换该行：

Range(c).Offset(j, 0).Value = vFileList(i)

使用一些代码打开该工作簿并调用代码生成图表。如果你遇到困难，请告诉我。

进一步更新

我已经查看了上面提到的代码并进行了一些改进，包括一个额外的参数，用于指定要针对打开的每个工作簿（满足指定条件）运行的宏的名称。您在调用中使用的宏必须存在于您正在调用所有其他工作簿的工作簿中（例如，如果图表宏位于您的个人工作簿中，则下面的代码也应放在您的个人宏工作簿中）：< / p>

Option Explicit

Sub FileLoop(pDirPath As String, _
             Optional pPrintToSheet = False, _
             Optional pStartCellAddr = "$A$1", _
             Optional pCheckCondition = False, _
             Optional pFileNameContains = "xxx", _
             Optional pProcToRunOnWb)

On Error GoTo PrintFileList_err

    ' Local constants / variables
    Const cProcName = "FileLoop"
    Dim vFileList() As String ' array for file names
    Dim i As Integer          ' iterator for file name array
    Dim j As Integer          ' match counter
    Dim c As String
    ' variables for optional param pProcToRunOnWb
    Dim vFullPath As String
    Dim vTmpPath As String
    Dim wb As Workbook

    vFullPath = Application.ThisWorkbook.FullName
    vFileList = GetFileList(pDirPath)
    c = pStartCellAddr
    j = 0

    For i = LBound(vFileList) To UBound(vFileList)
        ' if condition is met (i.e. filename cotains text or condition is not required...
        If pCheckCondition And InStr(1, vFileList(i), pFileNameContains, vbTextCompare) > 0 _
           Or Not pCheckCondition Then

            ' print name to sheet if required...
            If pPrintToSheet Then
                Range(c).Offset(j, 0).Value = vFileList(i)
                j = j + 1 ' increment row offset
            End If

            ' open wb to run macro if required...
            If pProcToRunOnWb <> "" Then
                Application.DisplayAlerts = False ' set alerts off so that macro can run in other wb
                vTmpPath = pDirPath & "\" & vFileList(i)
                Set wb = Workbooks.Open(Filename:=vTmpPath)
                Workbooks(wb.Name).Activate
                Application.Run "'" & vFullPath & "'!" & pProcToRunOnWb
                wb.Close (True) ' save and close workbook
                Application.DisplayAlerts = True ' set alerts back on
            End If

        End If

        Debug.Print vFileList(i)
    Next i

   ' clean up
   Set wb = Nothing

PrintFileList_exit:
    Exit Sub

PrintFileList_err:
    Debug.Print "Error in ", cProcName, vbCrLf, "Err no: ", Err.Number, _
                vbCrLf, "Err Description: ", Err.Description
    Resume Next

End Sub

Function GetFileList(pDirPath As String) As Variant
On Error GoTo GetFileList_err

    ' Local constants / variables
    Const cProcName = "GetFileList"
    Dim objFSO As Object
    Dim objFolder As Object
    Dim objFile As Object
    Dim c As Double           ' upper bound for file name array
    Dim i As Double           ' iterator for file name array
    Dim vFileList() As String ' array for file names

    Set objFSO = CreateObject("Scripting.FileSystemObject")
    Set objFolder = objFSO.GetFolder(pDirPath)
    c = objFolder.Files.Count
    i = 0

    ReDim vFileList(1 To c)  ' set bounds on file array now we know count

    'Loop through the Files collection
    For Each objFile In objFolder.Files
        'Debug.Print objFile.Name
        i = i + 1
        vFileList(i) = objFile.Name
    Next

    'Clean up!
    Set objFolder = Nothing
    Set objFile = Nothing
    Set objFSO = Nothing

    GetFileList = vFileList

GetFileList_exit:
    Exit Function

GetFileList_err:
    Debug.Print "Error in ", cProcName, vbCrLf, "Err no: ", Err.Number, _
                vbCrLf, "Err Description: ", Err.Description
    Resume Next

End Function

您可以使用所需的参数从另一个宏或直接窗口（ctrl + G）调用此方法，例如获取包含'.xls'的所有文件，并运行名为'your_macro_name_here'的宏，代码为：

call FileLoop("C:\Users\Prosserc\Dropbox\Docs\Stack_Overflow\Test", False, "", True, ".xls", "your_macro_name_here")

显然，将第一个参数中的路径更改为指向包含要运行宏的文件的目录。

Answer 2

python和perl都有一个名为Xlsxwriter的库，它允许图表生成的自动化。对于一些示例python代码，请参阅我的帖子here。

自动在多个excel文件中创建图表？

2 个答案: