Question

我在FixtureAdapter中实现了queryFixtures，以便能够进行“更复杂”的查询。我是这样做的（这是CoffeeScript）：

App.Store = DS.Store.extend {
  revision: 13
  adapter: DS.FixtureAdapter.extend {
    queryFixtures: (fixtures, query, type) ->
      console.log fixtures.get('length') # 2
      fixtures = fixtures.filter (item) ->
        for prop of query
          if item[prop] != query[prop]
            return false
        return true
      console.log fixtures.get('length') # 1
      return fixtures
  }
}

这是我的个人资料模型+灯具：

App.Profile = DS.Model.extend {
  name: DS.attr('string')
  businessName: DS.attr('string')
  picture: DS.attr('string')
  isBusiness: DS.attr('boolean')
  conversations: DS.hasMany('App.Conversation')
}

App.Profile.FIXTURES = [
  {
    id: 1
    name: 'Jon Snow'
    picture: 'https://encrypted-tbn3.gstatic.com/images?q=tbn:ANd9GcRDMu58ECeoIUUSMNPCEwWv4QAp4fT1fxXNK5AxK15I6GsAiBLC5Rl50zuOGQsDOedXbfE'
    isBusiness: false
    conversations: [101, 102]
  }
  {
    id: 2
    name: 'Jaime Lannister'
    picture: 'https://encrypted-tbn0.gstatic.com/images?q=tbn:ANd9GcQB_K_IfaK-da-TbwgoM1NogXSc7QPVlaxaET76D8sdMoxAd1C2WCvnsKIM8-sGFpmiPPQ'
    isBusiness: true
    businessName: 'Westeros Inc.'
    conversations: [103]
  }
]

出于测试目的，我在ApplicationRoute的init方法中对Profile进行查询：

App.ApplicationRoute = Ember.Route.extend {

  init: ->
    profiles = App.Profile.find { isBusiness: false }
    console.log profiles.get('length') # 0 ??

  model: ->
    return App.Profile.find()

}

如您所见，我在不同的地方记录了fixtures.get（'length'）。

适配器中的第一个console.log返回“2”，这是配置文件的总数（OK）。适配器中的第二个console.log返回“1”，表示过滤器正在运行（OK）。但我不明白为什么路由器中的第三个console.log返回“0”。这就像数据没有正确返回......

我不确定我做错了，如果它是Ember Data中的错误，或者它是否是预期的行为。有什么想法吗？

仅供参考，这是我的Ember配置：

Ember.VERSION : 1.0.0-rc.6
Handlebars.VERSION : 1.0.0-rc.4
jQuery.VERSION : 2.0.3

Answer 1

console.log输出长度为0，因为fixtureAdapter正在模拟异步查询。要将查询结果大小记录到控制台，请使用then，如：

App.ApplicationRoute = Ember.Route.extend {

  init: ->
    profiles = App.Profile.find { isBusiness: false }
    profiles.then (data) ->
      console.log 'count: ', data.get('length') # 1

  model: ->
    return App.Profile.find()

}

JSBIN：http://jsbin.com/utasuh/1/edit

queryFixtures总是返回0结果

1 个答案: