Question

由于某些原因，我只能使用IO :: Socket来构建我的小型http服务器（而不是其他专用的模块）。

EDIT1：我编辑了我的问题，我想知道我可以用什么来代替注释行“#last ...”

这是我的剧本：

use strict;
use IO::Socket;

my $server = IO::Socket::INET->new(LocalPort => 6800,
    Type => SOCK_STREAM,
    Reuse => 1,
    Listen => 10) or die "$@\n";
my $client ;

while ( $client = $server->accept()) {

    my $client_info;
    while(<$client>) {
        #last if /^\r\n$/;
        print "received: '" . $_ . "'\n";
        $client_info .= $_;
    }

    print $client "HTTP/1.0 200 OK\r\n";
    print $client "Content-type: text/html\r\n\r\n";

    print $client '<H1>Hello World(!), from a perl web server</H1>';
    print $client '<br><br>you sent:<br><pre>' . $client_info . '</pre>';

    close($client);
}

现在，当我发送POST请求时，它（脚本）没有考虑最后一行（POST数据）：

wget -qO- --post-data='hello=ok' http://127.0.0.1:6800
<H1>Hello World(!), from a perl web server</H1><br><br>you sent:<br><pre>POST / HTTP/1.1
User-Agent: Wget/1.14 (linux-gnu)
Accept: */*
Host: 127.0.0.1:6800
Connection: Keep-Alive
Content-Type: application/x-www-form-urlencoded
Content-Length: 8
</pre>

脚本输出为：

perl server.pl 
received: 'POST / HTTP/1.1
'
received: 'User-Agent: Wget/1.14 (linux-gnu)
'
received: 'Accept: */*
'
received: 'Host: 127.0.0.1:6800
'
received: 'Connection: Keep-Alive
'
received: 'Content-Type: application/x-www-form-urlencoded
'
received: 'Content-Length: 8
'

Answer 1

这是可以预料的。 POST请求看起来像

POST / HTTP/1.1
Header: Value

Data=Value

您在标题结束后终止处理，但数据在正文中！

如果您真的想编写自己的HTTP服务器，那么您应该从标头中提取HTTP方法。如果是POST，您可以查看Content-length标头中的值，并读取该字节数：

read $client, my $post_data, $content_length;

WRT更新的问题：

如果您想构建一个生产HTTP服务器，那么您将度过一段美好时光。这个东西很难。请仔细阅读perlipc，其中涉及TCP服务器主题。然后，您可以在此基础上实现HTTP的子集。

另请阅读CPAN上实现服务器的模块。即使您无法在系统上编译模块，也可以使用纯Perl模块，或者可以找到可以重用的代码部分。 CPAN的大部分可以在GPL许可下使用。

如果你想这样做，那就做吧。给自己写一个解析HTTP请求的子程序。这是一个不处理编码字段等的草图：

use strict; use warnings; use autodie;

BEGIN { die "Untested code" }

package Local::HTTP::Request {
  sub new {
    my ($class, $method, $path, $version, $header_fields, $content) = @_;
    ...;
  }
  ...; # accessors
  sub new_from_fh {
    my ($class, $fh) = @_;
    local $/ = "\015\102"; # CRLF line endings
    chomp(my $first_line = <$fh>);
    my ($method, $path, $version) = ...; # parse the $first_line

    # this cute little sub parses a single field incl. continuation
    # and returns the next line as well.
    my $parse_a_field = sub {
      chomp(my $line = shift);
      my ($name, $value) = split /:\s+/, $line, 2;
      while(defined(my $nextline = <$fh>)) {
        # handle line continuation
        if ($nextline =~ s/^[ \t]//) {
          chomp $nextline;
          $value .= $nextline;
        } else {
          return $name, $value, $nextline;
        }
      }
    };

    my %fields;
    my $line = <$fh>;
    until ($line eq $/) {
      (my $name, my $value, $line) = $parse_a_field->($line);
      $fields{lc $name} = $value;
    }

    read $fh, my $content, $fields{"content-length"} // 0;

    return $class->new( ... );
  }
}

然后在accept循环中

 my $request = Local::HTTP::Request->new_from_fh($client);

 print $client "HTTP/1.0 200 OK", "\015\012";
 print $client "Content-type: text/plain", "\015\012";
 print $client "\015\012";
 print $client "Request body:\n";
 print $client $request->content;

IO :: Socket服务器和POST数据的小问题

1 个答案: