在oracle 11g中重置序列

Question

我正在尝试使用oracle 11g中的以下过程动态地将序列重置为1.

create or replace
procedure reset_sequence(p_seq in varchar2)
is
    l_value number;
begin

-- Select the next value of the sequence

    execute immediate
    'select ' || p_seq || 
    '.nextval from dual' INTO l_value;

-- Set a negative increment for the sequence, 
-- with value = the current value of the sequence

    execute immediate
    'alter sequence ' || p_seq || 
    ' increment by -' || l_value || ' minvalue 0';

-- Select once from the sequence, to 
-- take its current value back to 0

    execute immediate
    'select ' || p_seq || 
    '.nextval from dual' INTO l_value;

-- Set the increment back to 1

    execute immediate
    'alter sequence ' || p_seq || 
    ' increment by 1 minvalue 0';
end;
/

但是当我尝试执行重置序列 circle_seq 的过程时，我收到以下错误

BEGIN reset_sequence(vf_circle_seq); END;

                     *
ERROR at line 1:
ORA-06550: line 1, column 22:
PLS-00357: Table,View Or Sequence reference 'CIRCLE_SEQ' not allowed 
           in this context
ORA-06550: line 1, column 7:
PL/SQL: Statement ignored

代码有什么问题？这在oracle 11g中是不可能的，因为我在oracle 10g中使用的相同代码才能正常工作。

Answer 1

序列名称应作为字符串传递

BEGIN 
  reset_sequence('vf_circle_seq'); 
END;