Question

我正在尝试在coffeescript中执行此操作，

具体来说，我正在尝试向我的jQWordCloud添加处理程序，以获取被单击的单词的标签

在我的coffeescript版本中

while i < @counts.length
  x = @counts[i]
  @tag_list.push
    text: x.label
    weight: x.count
    handlers:
      click: ->
        temp = x
        ->
          alert "it worked for " + temp.label
      ()
  ++i

我得到一个意外的TERMINATOR错误，大概是因为（），但如果你注意到jsfiddle，删除它会破坏处理程序

Answer 1

解决此问题的常见CoffeeScript方法是使用do：

当使用JavaScript循环生成函数时，通常会插入一个闭包装，以确保循环变量被关闭，并且所有生成的函数不只是共享最终值。 CoffeeScript提供do关键字，它立即调用传递的函数，转发任何参数。

然后只使用普通for ... in而不是while循环，这样您就不必使用索引;更像是这样的东西：

for o in stuff
  do (o) ->
    tag_list.push
      text: o.NAME
      weight: o.COUNT
      html:
        title: "#{o.COUNT} varieties"
      handlers:
        click: -> console.log("it worked for", o)

演示：http://jsfiddle.net/ambiguous/3W9YC/

或者你可以使用这样的循环理解：

tag_list = for o in stuff
  do (o) ->
    text: o.NAME
    weight: o.COUNT
    html:
      title: "#{o.COUNT} varieties"
    handlers:
      click: -> console.log("it worked for", o)

并避免push来电。

演示：http://jsfiddle.net/ambiguous/3W9YC/1/

顺便说一下，您可以在jsfiddle.net上使用CoffeeScript，方法是在侧栏的 Languages 面板中选择它。

Coffeescript jQCloud处理程序

1 个答案: