Question

我有一个项目，我们正在处理的主文件是一个旧的XML文件，其中创建者创建了一个非结构化的DTD（所有元素都是可选的，可以发生0次或更多次。更好的是读取文件的应用程序实际上期望许多值是必需的）。我根据已知的应用程序要求创建了一个XSD，并将无序元素列表移动到XSD中的序列中。

是否有一个简单的转换过程（例如XSLT）可以获取旧的XML文件，并以指定的方式对其元素进行排序，以便我们可以使用新的XSD来验证它？

示例：

<Top>
  <A/>
  <D/>
  <B/>
  <C/>
  <A/>
</TOP>

INTO

<Top>
  <A/>
  <A/>
  <B/>
  <C/>
  <D/>
</TOP>

此外，儿童也可能需要将元素分类到新的序列预期排序中。谢谢！

Answer 1

您可以以更具说明性的方式使用样式表中嵌入的“查找列表”，而不是在模板中指定要排序的所有元素：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet version="1.0"
   xmlns:xsl="http://www.w3.org/1999/XSL/Transform" 
   xmlns:my="my-namespace" 
   exclude-result-prefixes="my">
  <xsl:output method="xml" version="1.0" encoding="UTF-8" indent="yes"/>
  <my:Top>
    <my:A>
      <my:AA/>
      <my:AB/>
      <my:AC/>
    </my:A>
    <my:B/>
    <my:C/>
    <my:D/>
  </my:Top>
  <xsl:template match="my:*">
    <xsl:param name="source"/>
    <xsl:variable name="current-lookup-elem" select="current()"/>
    <xsl:for-each select="$source/*[name()=local-name($current-lookup-elem)]">
      <xsl:copy>
        <xsl:apply-templates select="$current-lookup-elem/*">
          <xsl:with-param name="source" select="current()"/>
        </xsl:apply-templates>
        <xsl:copy-of select="text()"/>
      </xsl:copy>
    </xsl:for-each>
  </xsl:template>
  <xsl:template match="/Top">
    <xsl:apply-templates select="document('')/*/my:*">
      <xsl:with-param name="source" select="/"/>
    </xsl:apply-templates>
  </xsl:template>
</xsl:stylesheet>

此示例：

<Top>
  <A>
    <AC/>
    <AA/>
  </A>
  <D/>
  <B/>
  <C>yyy</C>
  <A>
    <AB/>
    <AC/>
    <AA>xxx</AA>
  </A>
</Top>

将返回：

<Top>
    <A>
        <AA>xxx</AA>
        <AC/>
    </A>
    <A>
        <AA/>
        <AB/>
        <AC/>
    </A>
    <B/>
    <C>yyy</C>
    <D/>
</Top>

Answer 2

我假设你不想按字母顺序排列元素，而是按照你指定的顺序排列它们。试试这个 - 你需要一个XSLT处理器（例如Saxon），并将此文件保存为* .xsl。

<?xml version="1.0" encoding="UTF-8" ?>
<xsl:stylesheet version="1.0"
 xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" method="xml" version="1.0" />

<xsl:template match="Top">
   <xsl:copy>
      <xsl:for-each select="A">
         <xsl:copy-of select="." />  
      </xsl:for-each> 
      <xsl:for-each select="B">
         <xsl:copy-of select="." />  
      </xsl:for-each>  
      <xsl:for-each select="C">
         <xsl:copy-of select="." />  
      </xsl:for-each>  
      <xsl:for-each select="D">
         <xsl:copy-of select="." />  
      </xsl:for-each>
   </xsl:copy>  
</xsl:template>

</xsl:stylesheet>

但需要注意的是：XML区分大小写，因此您的<Top>和</TOP>标记不匹配，因此您没有格式良好的XML，因此XSLT处理器将抛出一个错误并退出。

<xsl:copy-of>复制匹配的元素及其所有子元素（包括属性）。要重新排序更深层次，您可以将xsl:copy-of替换为xsl:copy，然后从那里调用类似的模板以按顺序输出下一级别。

将XML转换为指定的顺序（DTD - ＆gt; XSD）

2 个答案: