使用exslt：node-set（）在xslt-1.0中进行XML到csv的转换

Question

我希望借助xslt-1.0将输入xml转换为csv输出。 以下是我的输入xml 格式。

     <input>
     <add add-value="First Name">
        <value type="string">New</value>
      </add>
       <add add-value="Surname">
        <value  type="string">user1</value>
      </add>
      <add add-value="Title">
        <value type="string">engineer</value>
     </add>
     <add add-value="Description">
        <value type="string">New joinee.</value>
      </add>
<add .....
</add>
    </input>

输出csv由固定数量的列组成，我通过xslt中的变量提供这些列。

以下是我的xslt：

     <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="http://exslt.org/common" >   
        <xsl:variable name="delimiter" select="','"/>   
        <xsl:template match="input/add">
            <xsl:variable name="SplitWordsSet">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
                </xsl:call-template>
            </xsl:variable>
            <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

            <xsl:call-template name="counter">
                <xsl:with-param name="split-words" select="$vSplitWords"/>
                <xsl:with-param name="count"select="1"/>
            </xsl:call-template>
        </xsl:template> 
<!-- Below templtate splits the pText values -->
        <xsl:template name="split">
            <xsl:param name="pText"/>
            <xsl:param name="pElemName" select="'word'"/>
            <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
            <xsl:variable name="remaining" select="substring-after($pText,',')"/>
            <xsl:element name="{$pElemName}">
                <xsl:value-of select="$first"/>
            </xsl:element>
            <xsl:choose>
                <xsl:when test="$remaining">
                    <xsl:call-template name="split">
                        <xsl:with-param name="pText" select="$remaining"/>
                        <xsl:with-param name="pElemName" select="$pElemName"/>
                    </xsl:call-template>
                </xsl:when>
            </xsl:choose>
        </xsl:template> 
<!-- below is recursive template to maintain count of columns values -->
        <xsl:template name="counter">
            <xsl:param name="count" select="1"/>
            <xsl:param name="split-words"/>
            <xsl:variable name="split-word" select="$split-words[$count]"/>
            <xsl:if test="$count &lt; 6">
                <xsl:call-template name="output-csv">
                    <xsl:with-param name="field-value" select="*[(@add-value = '$split-word')]/value"/>
                </xsl:call-template>
                <xsl:value-of select="$delimiter"/>
                <xsl:call-template name="counter">
                    <xsl:with-param name="count" select="$count + 1"/>
                </xsl:call-template>
            </xsl:if>
        </xsl:template>     
        <xsl:template name="output-csv">
            <xsl:param name="field-value"/>
        <xsl:value-of select="$field-value"/>
        </xsl:template>
    </xsl:stylesheet>

我感兴趣的add-value属性作为pText param传递。这些值是输出csv中的我的列。

我的预期输出：

First name,Surname,Phone number,Description,Title
New,User1,,New joinee,engineer

但是我无法获得所需的输出。我只得到逗号,,,,, 请有人指出我哪里出错了。

Answer 1

您的XSLT中存在一些问题。首先，在初始模板匹配时，您匹配添加元素，但由于它是输入元素，表示CSV文件中的一行，您可能希望匹配就那个

<xsl:template match="input">

然后，当您调用 output-csv 模板时，您应该寻找具有相应 add-value 属性的 add 元素对于当前的话。

<xsl:call-template name="output-csv">
   <xsl:with-param name="field-value" select="add[@add-value = $split-word]/value"/>
</xsl:call-template>

您的主要问题是如何以递归方式调用计数器模板。您没有在此处重新设置拆分字属性，因此在第二次调用时，参数将为空。

 <xsl:call-template name="counter">
    <xsl:with-param name="count" select="$count + 1"/>
 </xsl:call-template>

（也许值得指出的是，在你的XML中你有第一个属性为'First Name'，但在XSLT的列名列表中，它是'名字'.XSLT中的字符串比较是区分灵敏）。

你可以在这里设置参数，但是将分割词列表设为全局变量可能更好（当然更有效），而不是为每个输入元素分割它们。

试试这个XSLT

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="urn:schemas-microsoft-com:xslt" >   
    <xsl:variable name="delimiter" select="','"/>
   <xsl:variable name="SplitWordsSet">
     <xsl:call-template name="split">
       <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
     </xsl:call-template>
   </xsl:variable>
   <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

    <xsl:template match="input">
        <xsl:call-template name="counter">
            <xsl:with-param name="count" select="1"/>
        </xsl:call-template>
    </xsl:template> 

  <!-- Below templtate splits the pText values -->
    <xsl:template name="split">
        <xsl:param name="pText"/>
        <xsl:param name="pElemName" select="'word'"/>
        <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
        <xsl:variable name="remaining" select="substring-after($pText,',')"/>
        <xsl:element name="{$pElemName}">
            <xsl:value-of select="$first"/>
        </xsl:element>
        <xsl:choose>
            <xsl:when test="$remaining">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="$remaining"/>
                    <xsl:with-param name="pElemName" select="$pElemName"/>
                </xsl:call-template>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

 <!-- below is recursive template to maintain count of columns values -->
    <xsl:template name="counter">
        <xsl:param name="count" select="1"/>
        <xsl:param name="split-words"/>

        <xsl:variable name="split-word" select="$vSplitWords[$count]"/>
        <xsl:call-template name="output-csv">
          <xsl:with-param name="field-value" select="add[@add-value = $split-word]/value"/>
        </xsl:call-template>
        <xsl:if test="$count &lt; 5">
            <xsl:value-of select="$delimiter"/>
            <xsl:call-template name="counter">
                <xsl:with-param name="count" select="$count + 1"/>
            </xsl:call-template>
        </xsl:if>
    </xsl:template>     
    <xsl:template name="output-csv">
        <xsl:param name="field-value"/>
    <xsl:value-of select="$field-value"/>
    </xsl:template>
</xsl:stylesheet>

这应该给你输出

 New,user1,,New joinee.,engineer

但是，您可以采用另一种方法，而不使用递归模板。拥有与您的拆分字元素相匹配的模板，并将当前的输入作为参数传递

   <xsl:template match="word">
     <xsl:param name="input" />
     <xsl:if test="position() > 1">
       <xsl:value-of select="$delimiter"/>
     </xsl:if>
     <xsl:value-of select="$input/add[@add-value = current()]/value" />
   </xsl:template>

然后，每行可以像这样输出

      <xsl:apply-templates select="$vSplitWords">
        <xsl:with-param name="input" select="." />
      </xsl:apply-templates>

尝试这个XSLT

 <xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ext="urn:schemas-microsoft-com:xslt" >   
    <xsl:variable name="delimiter" select="','"/>

   <xsl:variable name="SplitWordsSet">
     <xsl:call-template name="split">
       <xsl:with-param name="pText" select="'First name,Surname,Phone number,Description,Title'"/>
     </xsl:call-template>
   </xsl:variable>
   <xsl:variable name="vSplitWords" select="ext:node-set($SplitWordsSet)/*"/>

    <xsl:template match="input">
      <xsl:apply-templates select="$vSplitWords">
        <xsl:with-param name="input" select="." />
      </xsl:apply-templates>
    </xsl:template> 

 <!-- Below templtate splits the pText values -->
    <xsl:template name="split">
        <xsl:param name="pText"/>
        <xsl:param name="pElemName" select="'word'"/>
        <xsl:variable name="first" select="substring-before(concat($pText,','),',')"/>
        <xsl:variable name="remaining" select="substring-after($pText,',')"/>
        <xsl:element name="{$pElemName}">
            <xsl:value-of select="$first"/>
        </xsl:element>
        <xsl:choose>
            <xsl:when test="$remaining">
                <xsl:call-template name="split">
                    <xsl:with-param name="pText" select="$remaining"/>
                    <xsl:with-param name="pElemName" select="$pElemName"/>
                </xsl:call-template>
            </xsl:when>
        </xsl:choose>
    </xsl:template>

   <xsl:template match="word">
     <xsl:param name="input" />
     <xsl:if test="position() > 1">
       <xsl:value-of select="$delimiter"/>
     </xsl:if>
     <xsl:value-of select="$input/add[@add-value = current()]/value" />
   </xsl:template>

</xsl:stylesheet>