Question

我需要知道如何在不使用XML的情况下从外部文件夹加载未知数量的图像

请帮助我，谢谢

Answer 1

因此，根据您的评论，我假设这是一个AIR应用程序，因此您可以通过File类访问文件系统。

首先，您需要获得指向您文件夹的File对象，最简单的方法是对其进行硬编码。稍微复杂一点的方法是打开一个对话框，用户可以在其中选择所需的文件夹（使用File.browseForOpen）。

让我们采用简单的路线并定义文件夹的常量路径，这里是用户文档文件夹中名为“images”的文件夹：

File imageFolder = File.documentsDirectory.resolvePath("images");

一旦我们有了文件夹实例，我们就可以使用getDirectoryListing方法列出该文件夹中的所有文件。这是一个例子：

// create a vector that will contain all our images
var images:Vector.<File> = new Vector.<File>();

// first, check if that folder really exists
if(imageFolder.exists && imageFolder.isDirectory){
    var files:Array = imageFolder.getDirectoryListing();

    for each(var file:File in files){
        // match the filename against a pattern, here only files
        // that end in jpg, jpeg, png or gif will be accepted
        if(file.name.match(/\.(jpe?g|png|gif)$/i)){
            images.push(file);
        }
    }
}

// at this point, the images vector will contain all image files
// that were found in the folder, or nothing if no images were found
// or the folder didn't exist.

要将文件加载到您的应用程序中，您可以执行以下操作：

for each(var file:File in images){
    // use a FileStream to read the file data into a ByteArray
    var stream:FileStream = new FileStream();
    stream.open(file, FileMode.READ);
    var bytes:ByteArray = new ByteArray();
    stream.readBytes(bytes);
    stream.close();

    // create a loader and load the image into it
    var loader:Loader = new Loader();

    // use the loadBytes method to read the data
    loader.loadBytes(bytes);

    // you can add the loader to the scene, so that it will be visible.
    // These loaders will all be at 0, 0 coordinates, so maybe change 
    // the x and y coordinates to something more meaningful/useful.
    this.addChild(loader);
}

Answer 2

你能详细说明这个问题吗？如果是用户操作（即用户需要上传一些照片），我会使用File API - 您可以看到示例here - 否则，如果是来自服务器端，我会使用PHP或Phyton剧本。

Answer 3

假设您的应用程序是 Air（桌面应用程序），此代码将非常有用：

<?xml version="1.0" encoding="utf-8"?>
<mx:WindowedApplication xmlns:mx="http://www.adobe.com/2006/mxml" layout="absolute" creationComplete="init()">
    <mx:Script>
        <![CDATA[
            public function init():void{
                var fs:FileStream = new FileStream();
                var f:File = new File("c:/imgTest.jpg");
                var b:ByteArray = new ByteArray();
                fs.open(f, FileMode.READ);
                fs.readBytes(b,0,fs.bytesAvailable);
                idImg.source  = b;
                fs.close();
            }
        ]]>
    </mx:Script>
    <mx:Image id="idImg" width="100%" height="100%"/>
</mx:WindowedApplication>

将图像放在 c：/imgTest.jpg 中。请注意，此图像位于项目路径之外。您还有其他选项可以加载图像，但这些选项必须可以通过URL访问，或者应该位于项目的路径中。这里有一个链接，可用于在Flex Air和Web中加载图像：

注意：我只尝试使用 JPG 文件，我不知道这是否适用于其他类型。

加载未知数量的外部图像而不使用XML

3 个答案: