Question

此宏的目的是创建一个宏，该宏为访问关联列表的某个键提供名称。

(defmacro generate-accessor (key-symbol prefix)
  (let ((mac-name 
          (intern (string-upcase (concatenate 'string
                                              prefix "-"
                                              (string key-symbol))))))
    `(defmacro ,mac-name (alis) `(assoc ,',key-symbol ,alis))))

所以当我尝试时 -

CL-USER> (generate-accessor 'a "alist")
; ERROR> 'A cannot be coerced to a string.

然而......

CL-USER> (string 'a)
; RESULT> "A"

所以我再次尝试使用SYMBOL-NAME将符号强制转换为字符串

(defmacro generate-accessor (key-symbol prefix)
  (let ((mac-name 
          (intern (string-upcase (concatenate 'string
                                              prefix "-"
                                              (symbol-name key-symbol))))))
    `(defmacro ,mac-name (alis) `(assoc ,',key-symbol ,alis))))

这次我试试 -

CL-USER> (generate-accessor 'a "alist")
; ERROR> The value 'A is not of type SYMBOL.

然而......

CL-USER> (symbol-name 'a)
; RESULT>"A"
CL-USER> (symbolp 'a)
; RESULT>T

每当我在宏之外使用'a时，它会像我期望的那样自动作为符号实现。然而，当我将'a传递给我的宏时，它以某个引用的块的形式到达。我不明白为什么它没有被评估，特别是在反引号开始之前。我知道我不理解Lisp的基本内容，但我现在不知道如何看待它。

Answer 1

'a是(quote a)的简写，这是您传递给宏的列表。宏参数不会被评估，但会按原样传递。当用作函数的参数（即不是宏）时，(quote a)首先评估，评估 (quote a)的结果是符号a。例如，考虑

之间的区别

(list 'a)           ===
(list (quote a)) 
; => (a)

和

'('a)               ===
'((quote a))        ===   
(quote ((quote a)))
; => ((quote a)) ;; which may also be printed ('a)

使用宏

的符号参数的示例

根据评论中的请求，这里是一个类似defstruct的宏，它创建了一些包含结构名称的函数。

(defmacro my-defstruct (name slot)
  "A very poor implementation of defstruct for structures
that have exactly one slot"
  (let ((struct-name (string name))
        (slot-name (string slot)))
    `(progn
       (defun ,(intern (concatenate 'string (string '#:make-) struct-name)) (value)
         (list value))
       (defun ,(intern (concatenate 'string (string struct-name) "-" slot-name)) (structure)
         (car structure)))))

以下是例如(my-defstruct foo bar)扩展为：

的内容

CL-USER> (pprint (macroexpand '(my-defstruct foo bar)))

(PROGN
 (DEFUN MAKE-FOO (VALUE) (LIST VALUE))
 (DEFUN FOO-BAR (STRUCTURE) (CAR STRUCTURE)))

使用示例：

CL-USER> (my-defstruct foo bar)
FOO-BAR
CL-USER> (make-foo 34)
(34)
CL-USER> (foo-bar (make-foo 34))
34

Answer 2

每当我使用'在我的宏之外时，它会像我期望的那样自动作为符号实现。

为什么。我希望它是一个引用的形式，在评估时我会得到引用的对象。

请记住：宏转换源代码，而不是评估对象。

由于您的代码未对其进行评估，并且您在引用的表单上调用SYMBOL-NAME，我认为这是一个错误。

您可以像其他代码一样调试宏。打印出宏作为参数的内容，或者只是使用调试器来查看回溯并查看各种变量值。

宏CHECK-TYPE检查某个地方的类型。

CL-USER 15 > (defmacro generate-accessor (key-symbol prefix)
               (check-type key-symbol symbol)
               (check-type prefix string)
               (let ((mac-name 
                      (intern (string-upcase (concatenate 'string
                                                          prefix "-"
                                                          (string key-symbol))))))
                 `(defmacro ,mac-name (alis) `(assoc ,',key-symbol ,alis))))
GENERATE-ACCESSOR

CL-USER 16 > (generate-accessor 'a "alist")

Error: The value (QUOTE A) of KEY-SYMBOL is not of type SYMBOL.
  1 (continue) Supply a new value of KEY-SYMBOL.
  2 (abort) Return to level 0.
  3 Return to top loop level 0.

所以CHECK-TYPE抱怨它不是一个符号，而是两个元素的列表。这是预期的，因为宏适用于源代码，而不是评估对象。

顺便说一句，将访问者编写为宏已经错了。 Common Lisp具有函数 - 使用它们。

Answer 3

显然你没有注意到调用宏时'a没有被评估：

(defmacro generate-accessor (**key-symbol** prefix)
  (let ((mac-name 
          (intern (string-upcase (concatenate 'string
                                              prefix "-"
                                              (string **key-symbol**))))))
    `(defmacro ,mac-name (alis) `(assoc ,',key-symbol ,alis))))

键符号只是替代而不是评估。例如，定义一个更简单的宏，如下所示：

(defmacro foo (a b)                                                                                          
  (let ((x a) (y b) (z (concatenate 'string (string a) b)))                                                  
    `(print (list ,a ,b ,x ,y ,z))))

传递'a和'b“：

CL-USER> (foo 'a "b")                                                                                        
; Evaluation aborted on #<SIMPLE-TYPE-ERROR expected-type: SB-KERNEL:STRING-DESIGNATOR datum: 'A>.

执行(setq a 1)后，传入a和“b”：

CL-USER> (foo a "b")                                                               
(1 "b" 1 "b" "Ab")                                                                                           
(1 "b" 1 "b" "Ab")

你可以发现 a （没有引号）只是字面上替换到let子句中，因为它没有eval逗号。

要解决此问题，您可以传入不带引号的符号，或者将宏重写为如下函数：

(defun generate-accessor (key-symbol prefix)
  (eval
    (let ((mac-name 
             (intern (string-upcase (concatenate 'string
                                                 prefix "-"
                                                 (string key-symbol))))))
      `(defmacro ,mac-name (alis) `(assoc ',key-symbol ,alis)))))

但这不是最终答案 - 在保持key-symbol不受影响的同时，您如何评价alis？我认为这是不可能的。

也许您可以将内部defmacro更改为defun：

(defun generate-accessor (key-symbol prefix)
  (eval
    (let ((mac-name 
           (intern (string-upcase (concatenate 'string
                                               prefix "-"
                                               (string key-symbol))))))
      `(defun ,mac-name (alis) (assoc ',key-symbol alis)))))

有效！

CL-USER> (generate-accessor 'a "x")                                                              
X-A

宏很强大，但不要过度使用！

Common Lisp：将符号传递给宏

3 个答案:

使用宏