Question

我的要求是将文件和文件夹从SFTP远程位置传输到unix位置。我是perl和shell脚本的新手，这一直非常令人困惑。我尝试使用sftp foreign中的rget命令，如下所示。但它不起作用，也没有转移。从sftp服务器复制后如何删除文件和文件夹？

use Net::SFTP::Foreign;

my $host       = "sftp.elsevier.com";
my $remote_dir = "sample/host";
my $localdir = "sample/local";
my $username   = "username";
my $password   = "password";
my $debug      = 0;

$sftp = Net::SFTP::Foreign->new($host, timeout => 240,user => $username, password => $password) or $newerr = 1;
push @ERRORS, "Can't sftp to $host: $!\n" if $newerr;
myerr() if $newerr;
print "Connected to $host\n";

$sftp->rget($remote_dir, $localdir) or $newerr = 1;
push @ERRORS, "Cant tranfer\n" if $newerr;
myerr() if $newerr;
$sftp->disconnect if $newerr;
print "Files are transferred successfully\n";

#Deleting files

$sftp->setcwd($remote_dir) or $newerr = 1;
push @ERRORS, "Can't cd $!\n" if $newerr;
myerr()    if $newerr;
$sftp->disconnect if $newerr;

my $files = $sftp->ls or $newerr = 1;
push @ERRORS, "Can't get file list $!\n" if $newerr;
myerr() if $newerr;

foreach (@$files){
$sftp->remove($_) or $newerr = 1;
push @ERRORS, "Cant delete\n" if $newerr;
myerr() if $newerr;

print "Deleted files successfully\n";

#}
$sftp->disconnect;

sub myerr {
    print "Error: \n";
    print @ERRORS;
    exit 0;
}

在SFTP位置 - 示例/主机内部，我有许多文件夹和文件都需要复制到本地unix服务器 - sample / local并从远程位置删除。

Answer 1

您需要获得一本好的Perl书籍，它将帮助您学习如何以更加现代的方式编写Perl代码。我推荐Learning Perl。这应该教你一些编码技巧。

例如，始终使用use strict;和use warnings;。这两个模块将捕获大约99％的编码错误。

此外，执行错误检查的标准方法是使用or die样式语法。这是一个比设置变量更自然的方法，然后检查变量，如果有错误，那么转到子程序：

$stfp->ls or die qq(Cannot access remote machine ) . HOST;

如果你缩进也会很好。使您的代码更容易跟随。

Perl有一个标准，变量应全部小写，最新标准是使用下划线来帮助分离变量名称。常量应该全部大写。

您还应该查看该模块的完整文档。例如，当您创建autodie对象时会出现Net::SFTP::Foreign选项，该对象会在任何失败时终止您的sftp会话。这简化了编码，因为您不必检查错误。

您还需要知道Net::SFTP::Foreign->ls会将引用返回给数组。因此，您需要取消引用该数组。您还必须知道此数组引用中的每个条目实际上是对散列的引用，并且文件名位于该散列引用的filename键下。

文档提到的另一个小事实：该程序使用Unix / Linux安装的ssh客户端。如果您没有安装ssh客户端，这将无效。

您可能希望查看References

上的Perl教程

我重写了你的程序以利用autodie并使用更现代的语法。通常，我会测试这个，但不幸的是，我没有安装Net :: SFTP :: Foreign，而且我没有可用于测试的远程计算机：

#! /usr/bin/env perl
use strict;
use warnings;
use feature qw(say);
use autodie;

use Net::SFTP::Foreign;

use constant {
    HOST            => "sftp.elsvier.com",
    REMOTE_DIR      => "sample/host",
    LOCAL_DIR       => "sample/local",
    USER_NAME       => "username",
    PASSWORD        => "password",
    DEBUG           => "0",
};

my $sftp;
$sftp = Net::SFTP::Foreign->new (
    HOST,
    timeout         => 240,
    user            => USER_NAME,
    password        => PASSWORD,
    autodie         => 1,
);

#
# Fetch Files
#
$sftp->rget( REMOTE_DIR, LOCAL_DIR );

#
# Delete Files
#

$sftp->setcwd( REMOTE_DIR );
my @files = @{ $sftp->ls };  #Returns a reference to an array of hashes

for my $file ( @files ) {
    $sftp->remove( $file->{filename} ); #Reference to a hash
}

say "Deleted files successfully";

$sftp->disconnect;

转移＆amp;使用SFTP外部模块从SFTP删除文件

1 个答案: