Question

我正在使用XSLT从专利商标局的商标XML文件中提取一些数据。除了一个空行外，它基本没问题。我可以通过适度丑陋的解决方法摆脱它，但我想知道是否有更好的方法。

这是我的XSLT的一个子集：

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:tm="http://www.wipo.int/standards/XMLSchema/trademarks" xmlns:pto="urn:us:gov:doc:uspto:trademark:status">
<xsl:output method="text" encoding="utf-8" />
<xsl:strip-space elements="*"/>
<xsl:template match="tm:Transaction">
<xsl:apply-templates select=".//tm:TradeMark"/>
<xsl:apply-templates select=".//tm:ApplicantDetails"/>
<xsl:apply-templates select=".//tm:MarkEvent"/>
</xsl:template>

<xsl:template match="tm:TradeMark">
MarkCurrentStatusDate,"<xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"/>"<xsl:text/>
ApplicationNumber,"<xsl:value-of select="normalize-space(tm:ApplicationNumber)"/>"<xsl:text/>
ApplicationDate,"<xsl:value-of select="normalize-space(tm:ApplicationDate)"/>"<xsl:text/>
RegistrationNumber,"<xsl:value-of select="normalize-space(tm:RegistrationNumber)"/>"<xsl:text/>
RegistrationDate,"<xsl:value-of select="normalize-space(tm:RegistrationDate)"/>"<xsl:text/>
<xsl:apply-templates select="tm:WordMarkSpecification"/>
<xsl:apply-templates select="tm:TradeMarkExt"/>
<xsl:apply-templates select="tm:PublicationDetails"/>
<xsl:apply-templates select="tm:RepresentativeDetails"/>
</xsl:template>

<xsl:template match="tm:WordMarkSpecification">
MarkVerbalElementText,"<xsl:value-of select="normalize-space(tm:MarkVerbalElementText)"/>"<xsl:text/>
</xsl:template>

它还有一些模板，但这就是它的要点。在输出的最开始，我总是在任何数据之前得到一个空行;我没有得到任何其他空白。我的规避是将两条线结合起来：

<xsl:template match="tm:TradeMark">
MarkCurrentStatusDate,"<xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"/>"<xsl:text/>

成一行：

<xsl:template match="tm:TradeMark">MarkCurrentStatusDate,"<xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"/>"<xsl:text/>

这很有效，如果没有什么比这更好的话我觉得我没关系，但它看起来不那么优雅，对我来说就像是一个傻瓜。没有其他模板需要这种处理（例如tm：WordMarkSpecification模板或之后的另外六个）），我很困惑为什么在这里需要它。有什么想法吗？

因为我可以看到XSLT中插入空行的特定点，我认为提供我正在测试的XML没有帮助，但如果你确实需要查看它，你可以在{{ 3}};它是该档案中的XML文件。

Answer 1

在模板的开头使用您在模板末尾使用的相同技巧，用空<xsl:text/>指令剪切样式表节点树：

<xsl:template match="tm:TradeMark">
<xsl:text/>MarkCurrentStatusDate,"<xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"/>"<xsl:text/>

Answer 2

就个人而言，当您需要组合静态文本和动态值时，我认为使用concat()更清晰：

<xsl:template match="tm:TradeMark">
  <xsl:value-of 
   select="concat(
   'MarkCurrentStatusDate,&quot;', normalize-space(tm:MarkCurrentStatusDate), '&quot;',
   'ApplicationNumber,&quot;', normalize-space(tm:ApplicationNumber), '&quot;',
   'ApplicationDate,&quot;', normalize-space(tm:ApplicationDate), '&quot;',
   'RegistrationNumber,&quot;', normalize-space(tm:RegistrationNumber), '&quot;',
   'RegistrationDate,&quot;', normalize-space(tm:RegistrationDate), '&quot;'
    )"/>
  <xsl:apply-templates select="tm:WordMarkSpecification"/>
  <xsl:apply-templates select="tm:TradeMarkExt"/>
  <xsl:apply-templates select="tm:PublicationDetails"/>
  <xsl:apply-templates select="tm:RepresentativeDetails"/>
</xsl:template>

这也可以解决您出现空白的问题。

Answer 3

请记住，您始终只需使用XML语法来忽略开始和结束标记分隔符内的行尾序列：

<xsl:template match="tm:TradeMark"
>MarkCurrentStatusDate,"<xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"
/>"ApplicationNumber,"<xsl:value-of select="normalize-space(tm:ApplicationNumber)"
/>"ApplicationDate,"<xsl:value-of select="normalize-space(tm:ApplicationDate)"
/>"RegistrationNumber,"<xsl:value-of select="normalize-space(tm:RegistrationNumber)"
/>"RegistrationDate,"<xsl:value-of select="normalize-space(tm:RegistrationDate)"
/>"<xsl:apply-templates select="tm:WordMarkSpecification"/>
<xsl:apply-templates select="tm:TradeMarkExt"/>
<xsl:apply-templates select="tm:PublicationDetails"/>
<xsl:apply-templates select="tm:RepresentativeDetails"/>
</xsl:template>

XML中没有规则标记的结束分隔符/>必须与标记的开始分隔符<位于同一行。标签内部的空白被忽略（无害的），行尾序列被视为空白。

Answer 4

如果您希望在没有额外换行符或空白区域的情况下发出所有文本，请将文字文本放在<xsl:text>元素内。

<xsl:template match="tm:TradeMark">
    <xsl:text>MarkCurrentStatusDate,"</xsl:text>
        <xsl:value-of select="normalize-space(tm:MarkCurrentStatusDate)"/>
    <xsl:text>"</xsl:text>
    <xsl:text>ApplicationNumber,"</xsl:text>
        <xsl:value-of select="normalize-space(tm:ApplicationNumber)"/>
    <xsl:text>"</xsl:text>
    <xsl:text>ApplicationDate,"</xsl:text>
        <xsl:value-of select="normalize-space(tm:ApplicationDate)"/>
    <xsl:text>"</xsl:text>
    <xsl:text>RegistrationNumber,"</xsl:text>
        <xsl:value-of select="normalize-space(tm:RegistrationNumber)"/>
    <xsl:text>"</xsl:text>
    <xsl:text>RegistrationDate,"</xsl:text>
        <xsl:value-of select="normalize-space(tm:RegistrationDate)"/>
    <xsl:text>"</xsl:text>
    <xsl:apply-templates select="tm:WordMarkSpecification"/>
    <xsl:apply-templates select="tm:TradeMarkExt"/>
    <xsl:apply-templates select="tm:PublicationDetails"/>
    <xsl:apply-templates select="tm:RepresentativeDetails"/>
</xsl:template>

这样，<xsl:template>内部的换行符和空白区域都不会被视为重要，并且不会包含在结果树输出中。

XSLT转换中的一个令人讨厌的空白行

4 个答案: