Question

我现在不是OOP和as3的专家。我正在制作能够处理这些事情的库存系统：
*当玩家与“物品”发生碰撞时，它会获得并发送到库存阵列等......

这是Player类构造函数
你可以看到我手动编写项目的实例名称：“silver_key”

public function Player(player:MovieClip,loot:MovieClip,place:MovieClip)
    {
        // constructor code
        _player = player;
        silver_key = loot;//the item

        _inventory = new InventorySystem(place);//InventorySystem Class

        _player.addEventListener(Event.ENTER_FRAME,on_enter_frame);

        addEventListener(EventDemo.EVENT_DEFAULT,onEvent);//custom event listener

    }

这是相对于它的功能：

private function on_enter_frame(e:Event):void
if (_player.hitTestObject(silver_key))//check collision between player and item
        {
            dispatchEvent(new EventDemo(EventDemo.EVENT_DEFAULT));

        }

private function onEvent(e:EventDemo)
    {
        _inventory.getitem(_loot);//function use in InventorySystem for array.push
        removeEventListener(EventDemo.EVENT_DEFAULT,onEvent);//removes the listener when the item was sent to array
    }

现在我的问题是如何在不手动编写实例名称的情况下创建大量项目。谢谢。
ps：如果你仍然无法理解，请发表评论。

Answer 1

简单地说：

object["string_name"] = value

如需更全面的解释，请继续阅读......

您需要为每个项目指定显式名称，但是您希望动态定义这些项目而不知道它们可能是什么。您可以通过多种方式存储它，但基本的数组或对象应该可以正常工作。

看起来你正在创建一个代表玩家的动画片段。作为一个类，玩家类的实例化本身可以是动画片段，但要注意MovieClip带有很多时间线的包袱，可能会减慢你的速度。对于更简洁/轻量级的播放器类，请扩展Sprite并编写自己的属性/方法。

例如，让我们假设这是Silver Key对象的样子：

item:Object = {
    "name":"Silver Key",
    "count":1,
    "weight":3,
    "icon":"silver_key.jpg"
}

在一个对象中，我们可以将name属性定义为我们想要的那种类型的项目，以及描述该项目的其他相关属性。现在，我们需要做的就是在播放器类本身中保存已保存项目的列表。

玩家等级

package {   
    public dynamic class Player extends Sprite {
        import flash.events.*;
        import flash.display.*;

        public var inventory:Object = {};

        public function Player() {
            addEventListener(Event.ENTER_FRAME, tick);
        }

        public function tick(e:Event):void {
            // ENTER_FRAME stuff
        }

        public function loot(item:Object) {
            if (inventory.hasOwnProperty(item.name)) {
                inventory.item.count++
                trace("You now have " + inventory.item.count + " " + item.name + "'s!");
            } else {
                inventory[item.name] = item;
                trace("You have picked up a " + item.name)
            }
        }

        public function drop(item:Object) {
            if (inventory.hasOwnProperty(item.name)) {
                inventory.item.count--
                if (inventory.item.count == 0) {
                    trace("You no longer have " + item.name);
                    delete(inventory[item.name]);
                } else {
                    trace("You now have one less " + item.name + ".");
                }
            }
        }
    }
}

示例实施

var player:Player = new Player();
player.loot(item);
// traces "You picked up a Silver Key"
player.drop(item);
// traces "You no longer have Silver Key"

这是一种简单的方法，实际上，您可能希望使用自己的项目进行扩展。库存类，以及数据清理/检查，以防止库存损坏。

更新： “很可能，您将创建每个项目的原型。”

这就是人们的样子。

package {   
    public class ItemDefinition extends Object {
        public var name:String = "Unnamed Item";
        public var count:int = 1;
        public var weight:int = 0;
        public var icon:String = "unnamed.jpg";

        public function ItemDefinition(Properties:Object) {
            // By passing in an object, we can define only the properties we want to change.
            for (var Name:String in Properties) {
                // Only property names that match will overwrite the defaults.
                if (this.hasOwnProperty(Name)) {
                    this[Name] = Properties[Name]
                }
            }
        }
    }
}

这有什么好处，我们可以按任意顺序定义任意数量的属性，而不必担心会添加一个可能会让我们后来搞砸的虚假值。此外，如果我们想要为定义Item的内容添加新属性，只需将其添加为顶部的public var。

接下来，我们可以使用新的ItemDefinition对象在文档顶部定义所有项目。

var itemDefinitions:Object = {
    'Silver Key':new Item({name:"Silver Key", icon:"silver_key.jpg", weight:3}),
    'Gold Key':new Item({weight:10, name:"Gold Key", icon:"gold_key.jpg"}),
    'Iron Key':new Item({icon:"iron_key.jpg", weight:2, name:"Iron Key"})
}

function populateItems(itemName:String, count:int = 20) {
    if (itemDefinitions.hasOwnProperty(itemName)) {
        for (var i:int = 0; i < count; i++) {
            var item:MovieClip = new MovieClip();
            item.x = randomNumber(0, this.loaderInfo.width);
            item.y = randomNumber(0, this.loaderInfo.height);
            item["itemDefinition"] = itemName;
        }
    } else {
        trace(itemName + " is an invalid item.");
    }
}

function randomNumber(low:Number=0, high:Number=1):Number {
    /* Returns a random number between the low and high values given. */
    return Math.floor(Math.random() * (1+high-low)) + low;
}

正如您所看到的，我添加了一些辅助函数来在屏幕上随机吐出这些额外的项目（随机）。显然，我们需要有一个addChild和图像加载，但这确实是你应该实现的。

最后，我们将修改我们的战利品调用以传递itemDefinition ...

player.loot(itemDefinitions[item.itemDefinition]);
removeChild(item);

世界的可能性。你可能会做出更强大的东西来满足你的游戏需求，所以这只是你可以做到的一种方式。

AS3游戏库存系统结构

1 个答案: