Question

在我们的类中，我们有一个模式，我们创建一个属性来表示一个计算值。出于显而易见的原因，我们想要缓存计算值然后在其中一个基础值发生更改时使缓存无效。

所以我们现在有这个：

package FooBar;
use Moose;

has 'foo' => (
        accessor => {
            'foo' => sub {
                my $self = shift;
                if (@_ > 0) {
                    # writer
                    $self->{foo} = $_[0];

      # reset fields that are dependant on me
      $self->{bar} = undef;
                }
                # reader part;
                return $self->{foo};
            }
        }
    );

has 'bar' => (
        accessor => {
            'bar' => sub {
                my $self = shift;
                if (@_ > 0) {
                    # writer
                    $self->{bar} = $_[0];
                }
                # reader part;
                $self->{bar} = calculate_bar($self->foo, $self->baz) 
                        if (not defined($self->{bar}));
                return $self->{bar};
            }
        }
    );

sub calculate_bar { ... }

这个长手法在计算值时变得非常乏味且容易出错取决于其他计算值。

是否有一种更智能/更简单的方法让'bar'监控它所依赖的属性与'foo'知道谁依赖它？另外我怎样才能避免通过哈希设置bar 会员访问？

Answer 1

如果我理解正确，您可以使用triggers清除属性。这是一个例子：

has 'foo' => (
    is      => 'rw',
    trigger => sub{
        my ($self) = @_;
        $self->clear_bar;
    }
);

has 'bar' => (
    is      => 'rw',
    clearer => 'clear_bar',
    lazy    => 1,
    default => sub{
        my ($self) = @_;
        return calculate_bar( ... );
    }
);

因此，通过foo对$obj->foo($newvalue)的任何写入都会导致bar被清除，并在下次访问时重新创建。

Answer 2

我认为你很可能通过使用带有懒惰的属性隐式记忆来使你自己变得更难，当你可以让memoization显式使你的整个程序更透明时

has [qw/foo bar baz/] => ( isa => 'Value', is => 'rw' );

use Memoize;
memoize('_memoize_this');

sub old_lazy_attr {
    my $self = shift;
    _memoize_this( $self->attr1, $self->attr2, $self->attr3 );
}

sub _memoize_this {
    my @args = @_;
    # complex stuff
    return $result
}

有关内部缓存的信息和控制，请参阅cpan的Memoize，还要记住，Memoized函数不能依赖于对象的状态。所以参数必须明确地传递。

Answer 3

这会有用吗？

#!/usr/bin/perl

package Test;

use Modern::Perl;
use Moose;

has a => (is => 'rw', isa => 'Str', trigger => \&change_a);
has b => (is => 'rw', isa => 'Str', trigger => \&change_b);
has c => (is => 'rw', isa => 'Str');

sub change_a
{
    my $self = shift;
    say 'update b';
    $self->b($self->a . ', bar');
}   

sub change_b
{
    my $self = shift;
    say 'update c';
}   

package main;

my $test = Test->new->a('Foo');

输出：

$ perl test.pl
update b
update c

Answer 4

我没有在Moose内部和元对象协议中做过任何讨论，但我认为这是一个很好的时机。

您希望修补代码生成，以便在将属性指定为

时

has 'foo' => ();
has 'bar' => ( 
    depends_on => [qw( foo )],
    lazy => \&calculate_bar,
);

代码生成阶段为您在上面指定的foo和bar属性创建代码。

如何做到这一点是留给读者的一个练习。如果我有线索，我会尝试给你一个开始。不幸的是，我能告诉你的是“这是MOP的工作”。

Moose：当属性值改变时，计算的缓存结果到期了吗？

4 个答案: