Question

Duting an automation我可以在本地保存文件，然后我需要使用QTP脚本将其上传到我的QC项目中的特定位置（以便稍后再次检索）。

关于如何做到这一点的任何想法？

非常感谢。

干杯。

Answer 1

Google是你的朋友。例如，来自http://h30499.www3.hp.com/t5/Quality-Center-Support-and-News/How-to-upload-a-any-type-of-file-to-quality-center-using-QTP/td-p/5297523#.UfpIs5JM_eQ的以下脚本看起来像是一个答案，并且是谷歌搜索“上传文件qc qtp”的首批点击之一：

Dim localFolderPath
localFolderPath = "Local folder path of library files"
call UploadFilesToQC("Subject\BPT RESOURCES\QC Folder Name", localFolderPath )

Public Function UploadFilesToQC(strQCPath,strFilesystemPath)  
    Dim fileCount, timeNow, timeOld, timeDiff
    fileCount = 0
    'Get QC connection object
    Set QCConnection = QCUtil.QCConnection
    'Get Test Plan tree structure
    Set treeManager = QCConnection.TreeManager
    Set node = treeManager.NodeByPath(strQCPath)
    Set AFolder = node.FindChildNode("Library Files")  ' Library Files folder Name in QC
    set oAttachment = AFolder.attachments
    timeOld = Now
    Set fso = CreateObject("Scripting.FileSystemObject")
    Set oFolder = fso.GetFolder(strFilesystemPath)
    Set oFiles = oFolder.Files
    'Iterate through each file present in File System path
    If oFiles.count >0 Then
    For Each oFile in oFiles
        Set attach = oAttachment.AddItem(Null)
        attach.FileName = oFile.Path
        attach.Type = 1
        attach.Post()
        fileCount = fileCount +1
        Set attach = nothing
    Next
    timeNow = Now
    timeDiff =     timeNow - timeOld
'Time required to upload all files to QC
    Reporter.ReportEvent micDone,"Time required to upload : ", "'" & timeDiff & "' minutes."
'Total Files count uploaded to QC
    Reporter.ReportEvent micDone,"Total files uploaded : ", "'" & fileCount & "' files uploaded."
    else
        Reporter.ReportEvent micFail,"File not found", "No file found at path: " & strFilesystemPath
    End If
End Function

通过QTP脚本将文件上传到QC中的特定文件夹

1 个答案: