Question

尝试修改XML文件时出现以下问题。我正在尝试将三个转换应用于下面的输入：

<sheet>
<row>
    <column_1>11</column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
</row>
</sheet>

1）将列移位/重命名为4，我能够使用以下XSLT来做到这一点：

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>
<xsl:template match="row/*">
    <xsl:element name="column_{substring(name(),8,string-length(name())-7)+4}">
        <xsl:apply-templates select="@* | node()" />
    </xsl:element>
</xsl:stylesheet>

收到的输出：

<sheet>
<row>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

2）在已存在的元素之前添加元素，以便收到以下输出：我不得不说我迷失了，因为没有想法如何让它发挥作用。

<sheet>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5></column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

3）包含以下用于传播数据的XSLT，如果它自己应用但是当与点1合并时它可以工作但是没有结果只有pint 1被应用

<?xml version="1.0" encoding="UTF-8"?>
<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="1.0">
<xsl:output indent="yes"/>
<xsl:template match="node() | @*">
<xsl:copy>
  <xsl:apply-templates select="node() | @*"/>
</xsl:copy>
</xsl:template>
<xsl:template match="column_5">
<xsl:copy>
  <xsl:choose>
    <xsl:when test=".=''">
      <xsl:value-of select="preceding::column_5[. != ''][1]"/>
    </xsl:when>
    <xsl:otherwise>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:otherwise>
  </xsl:choose>
</xsl:copy>
</xsl:template>
</xsl:stylesheet>

我的预期结果是：

<sheet>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
<row>
    <column_1></column_1>
    <column_2></column_2>
    <column_3></column_3>
    <column_4></column_4>
    <column_5>11</column_5>
    <column_6></column_6>
    <column_7></column_7>
</row>
</sheet>

谢谢， Lehu

Answer 1

它不漂亮，但是你走了。

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output indent="yes" />

  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="row">
    <xsl:copy>
      <column_1 />
      <column_2 />
      <column_3 />
      <column_4 />
      <xsl:apply-templates select="*" />
    </xsl:copy>
  </xsl:template>

  <xsl:template match="row/*">
    <xsl:element name="column_{substring-after(name(), 'column_') + 4}">
      <xsl:apply-templates select="@* | node()" />
    </xsl:element>
  </xsl:template>

  <xsl:template match="column_1[. = '']">
    <column_5>
      <xsl:value-of select="preceding::column_1[. != ''][1]/text()" />
    </column_5>
  </xsl:template>

</xsl:stylesheet>

使用XSLT 1.0重命名和添加新元素

1 个答案: