Question

我目前正在开发flashdevelop中的一个项目，我想要包含一些音乐。我正在构建一个游戏，因此不能选择多个文件。目前所有资源都是嵌入式的，并且一个简单的预加载器会加载所有内容（例如flashdevelop默认预加载器）。我不想在开头加载音乐，我宁愿在必要时播放它。

是否可以流式传输嵌入式声音？如果没有，是否可以将这些文件嵌入.swf文件并稍后加载？

提前致谢！

Answer 1

你可以做两件事。一种是在初始加载完成后开始加载声音并将它们保存在Dictionary中。其次是从Flash导出RSL（运行时共享库），这是一个SWF文件，然后您可以加载该文件并访问那里定义的所有类。

在第一种方法中，你基本上加载这样的每个声音并将它们保存到字典中：

import flash.media.Sound;
import flash.events.Event;
import flash.net.URLRequest;
import flash.utils.Dictionary;

var mSounds:Dictionary = new Dictionary();

function loadSound(url:String, soundName:String)
{
    var sound:Sound = new Sound();
    sound.addEventListener(Event.COMPLETE, onSoundLoadComplete);
    sound.load(new URLRequest(url));

    function onSoundLoadComplete(e:Event):void
    {
        sound.removeEventListener(Event.COMPLETE, onSoundLoadComplete);
        trace(soundName,"Sound Loaded");

        mSounds[soundName] = sound; // save it to dictionary

        // then you can load it from dictionary 
        // using the name you assigned
        if(mSounds["crystalised"])
            (mSounds["crystalised"] as Sound).play();
    }
}


loadSound("C:\\Users\\Gio\\Desktop\\Crystalised.mp3", "crystalised");

在第二种方法中，您必须执行更多步骤，但是只需加载一次。我将列出这里的步骤：

制作新的Flash文档（FLA）
将所需的所有声音导入库中
在每个声音的属性菜单中选择Actionscript选项卡并勾选Export for Runtime Sharing复选框并填写输出SWF的名称

发布此FLA后，您可以将其加载到您的应用程序或游戏中，并像这样使用它：

import flash.display.Loader;
import flash.system.LoaderContext;
import flash.system.ApplicationDomain;
import flash.system.SecurityDomain;
import flash.events.Event;
import flash.net.URLRequest;
import flash.media.Sound;
import flash.utils.getDefinitionByName;

function loadRSL(url:String):void
{
    var loader:Loader = new Loader();
    var context:LoaderContext = new LoaderContext(false, ApplicationDomain.currentDomain);

    loader.contentLoaderInfo.addEventListener(Event.COMPLETE, onRSLLoadComplete);
    loader.load(new URLRequest(url), context);

    function onRSLLoadComplete(e:Event):void
    {
        loader.contentLoaderInfo.removeEventListener(Event.COMPLETE, onRSLLoadComplete);
        trace("RSL Loaded");

        // creating a new instance of the sound which is defined in RSL
        var soundClass:Class = getDefinitionByName("Crystalised") as Class;
        var sound:Sound = (new soundClass() as Sound);
        sound.play();
    }
}

loadRSL("SoundLibrary.swf");

Flash / AS3 - 预加载或流式传输嵌入式声音

1 个答案: