Question

我花了很多时间来调试我追溯到wantarray()的问题。我把它提炼到这个测试用例。（忽略$!在这种情况下没有任何有用信息的事实。我想知道的是为什么wantarray不认为它在第二个例子中的LIST上下文中被调用：

#!/usr/bin/env perl

use strict;
use warnings;
use Test::More;

{
    my ( $one, $two ) = foo();
    is( $one, 'a', 'just foo' );
    is( $two, 'b', 'just foo' );
}

{
    my ( $one, $two ) = foo() || die $!;
    is( $one, 'a', '|| die' );
    is( $two, 'b', '|| die' );
}


done_testing();

sub foo {
    return wantarray ? ( 'a', 'b' ) : 'bar';
}

此测试的输出是：

$ prove -v wantarray.pl
wantarray.pl ..
ok 1 - just foo
ok 2 - just foo
not ok 3 - || die
not ok 4 - || die
1..4

#   Failed test '|| die'
#   at wantarray.pl line 15.
#          got: 'bar'
#     expected: 'a'

#   Failed test '|| die'
#   at wantarray.pl line 16.
#          got: undef
#     expected: 'b'
# Looks like you failed 2 tests of 4.
Dubious, test returned 2 (wstat 512, 0x200)
Failed 2/4 subtests

Test Summary Report
-------------------
wantarray.pl (Wstat: 512 Tests: 4 Failed: 2)
  Failed tests:  3-4
    Non-zero exit status: 2
    Files=1, Tests=4,  0 wallclock secs ( 0.03 usr  0.01 sys +  0.02 cusr  0.00 csys =  0.06 CPU)
    Result: FAIL

Answer 1

因为它没有在列表上下文中调用。 ||在左侧强制使用标量上下文，在这种情况下左侧是表达式foo()。

你应该写

my ( $one, $two ) = foo() or die $!;

or运算符比赋值运算符更松散地绑定，所以现在它的LHS是整个表达式my ($one, $two) = foo()，而foo的上下文由列表赋值运算符决定，每个人都很开心。

Answer 2

原因是||运算符的优先级。你的陈述基本上是这样解析的：

my ( $one, $two ) = ( foo() || die $! );

在这种情况下，||将其操作数置于标量上下文中。

另一方面，如果您将||更改为优先级低得多的or，则您的测试将通过。

Answer 3

逻辑或（||）是一个标量运算符，因此使用它会强制foo()的求值成为标量上下文。

试试这个：

my @a = 10 .. 100;
print(@a || 2), "\n";
# prints 91

如果不是因为数组已经在标量上下文中进行了评估，您希望这会打印@a中的元素。

为什么在调用foo（）||时，wantarray在标量上下文中返回死？

3 个答案: