Question

我有以下xml

  <Report>
     <Items>
       <Item>
        <Id>1</Id>
        <TotalSent>251</TotalSent>
        <Opened>48</Opened>
        <LastSend>01/07/2013 16:38:18</LastSend>
        <Bounced>1</Bounced>
        <Unopened>202</Unopened>
      </Item>
    </Items>
  </Report>

我想使用xslt将其转换为另一个xml，我想要的o / p如下所示

<chart subcaption ="Last sent on Monday 01 July 2013 at 16:38">
  <set label="Opened" value="48"/>
  <set label="Bounced" value="1"/>
</chart>

我无法获得 subcaption 属性的日期。我尝试了下面的xslt代码，但它无法正常工作

<?xml version="1.0" encoding="utf-8"?>
<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform" xmlns:ms="urn:schemas-microsoft-com:xslt">
<xsl:output method="xml" indent="yes" omit-xml-declaration="no"/>
<xsl:template match="/">
    <chart>
      <xsl:variable name='lastSend' select='Report/Items/Item/LastSend' />
      <xsl:attribute name="subcaption">
        <xsl:value-of select="ms:format-date($lastSend, ' Last sent on MMM dd, yyyy at')"/>
        <xsl:value-of select="ms:format-time($lastSend, ' hh:mm')"/>
      </xsl:attribute>
      <xsl:for-each select="Report/Items/Item">
        <set>
          <xsl:attribute name="label">Opened</xsl:attribute>
          <xsl:attribute name="value">
            <xsl:value-of select="Opened" />
          </xsl:attribute>
        </set>
        <set>
          <xsl:attribute name="label">Bounced</xsl:attribute>
          <xsl:attribute name="value">
            <xsl:value-of select="Bounced" />
          </xsl:attribute>
        </set>
      </xsl:for-each>
    </chart>
  </xsl:template>
</xsl:stylesheet>

当我在 ms：format-date（）＆amp;中传递硬编码值时ms：format-time（）函数，如01/07/2013 16:38:18它工作正常，但是当我传递变量值 $ lastSend 时，它无效。

注意：我可以使用任何版本的xsl。

Answer 1

如果要使用XSLT 2.0，则需要将自定义日期和dateTime格式转换为xs:dateTime，然后可以使用XSLT 2.0提供的format-dateTime函数（请参阅http://www.w3.org/TR/xslt20/#format-date）：

<xsl:template match="LastSend">
  <!-- 01/07/2013 16:38:18 -->
  <xsl:variable name="dt" as="xs:dateTime" select="xs:dateTime(concat(substring(., 7, 4), '-', substring(., 4, 2), '-', substring(., 1, 2), 'T', substring(., 12)))"/>
  <xsl:attribute name="subcaption" select="format-dateTime($dt, 'Last sent on [F] [D01] [MNn] [Y0001] at [H01]:[m01]')"/>
</xsl:template>

将上面的第二个参数“picture string”作为如何格式化dateTime的示例，您可能需要根据XSLT 2.0规范中记录的图片字符串参数调整它以满足您的需求。 / p>

格式化日期在xslt中

1 个答案: