Question

基本上这是我在google上编程过去半小时试图实现一个简单的事情的结果：从STDIN获取用户输入并将它们写入结构化XML文件作为输出，下面是我的丑陋的代码：

#!/bin/perl
print "img URL = ?    ";
$img = <>;
chomp($img);
print "filename = ?    ";
$filename = <>;
chomp($filename);

# now write xml with inserted contents to a file:
open (CARDFILE, ">>$filename");
print CARDFILE "<card>\r\n";
print CARDFILE "    <img>$img</img>\r\n";
print CARDFILE "    <type>$type</type>\r\n";
print CARDFILE "    <expansion>$expansion</expansion>\r\n";
print CARDFILE "    <keyword>$keyword</keyword>\r\n";
print CARDFILE "    <color>$color</color>\r\n";
print CARDFILE "    <linkcolor>$linkcolor</linkcolor>\r\n";
print CARDFILE "    <kickercolor>$kickercolor</kickercolor>\r\n";
print CARDFILE "    <cost>$cost</cost>\r\n";
print CARDFILE "    <strength>$strength</strength>\r\n";
print CARDFILE "    <health>$health</health>\r\n";
print CARDFILE "</card>";
close (CARDFILE);

我是Perl的新手，但我可以告诉我代码中的一些重要问题：

使用两行首先接收STDIN然后chomp()来消除尾随回车。应该有单行吗？
我无法弄清楚如何使用“here-doc”的东西一次打印多行文件。如果没有CARDFILE文件句柄，我可以使用here-doc语法在单个print语句中将所有字符串打印到STDOUT，现在我必须多次调用print函数。
对于这些"\r\n"，有没有办法使用不同的功能，所以我不必记得在每行之后手动插入它们？

Answer 1

读一行

阅读单行的习语是

chomp(my $var = <>);

但我通常最终会写一个小的prompt子程序：

sub prompt {
  print @_;
  chomp(my $answer = <>);
  return $answer;
}
...;
my $img = prompt("img URL = ? ");

在这里，文档

here-doc只是另一种字符串文字，例如

my $str = <<"END";
foo bar
baz
END
print $str;

如果用单引号括起分隔符：<<'END'，则无法将变量插入到here-doc中。请注意，结束标记必须始终位于行的开头，但可能包含空格字符：

    my $string = <<'END THIS';
    foo
    bar
END THIS
    # marker must be at start of line!

您可以直接打印像

这样的文档

print CARDFILE <<"END";
<card>
    <img>$img</img>
    <type>$type</type>
    <expansion>$expansion</expansion>
    <keyword>$keyword</keyword>
    <color>$color</color>
    <linkcolor>$linkcolor</linkcolor>
    <kickercolor>$kickercolor</kickercolor>
    <cost>$cost</cost>
    <strength>$strength</strength>
    <health>$health</health>
</card>
END

不同之处在于，除非使用Windows行结尾保存源文件，否则行末不会有\r\n。但是，here-doc确实包含物理换行符，并且总是以换行符结束。

印刷品

print函数打印由$,特殊变量分隔的参数，然后输出$\变量。默认情况下，这两个都是空的。但我们可以提供一个临时值：

local $\ = "123";
print "foo";

输出：

foo123

当然，我们通常会将其设置为\n。但有一条捷径：只需在源代码的开头加use feature 'say'或use 5.010（或更高），即可

say "foo";

会自动附加换行符。

打开文件句柄

使用词汇变量。使用三arg打开。做适当的错误处理。这意味着：

use autodie;
open my $fh, "<", "filename";

或

my $filename = "filename";
open my $fh, "<", $filename or die "Can't open $filename: $!";

第二个参数是模式，它将>>用于追加。明确指定它更安全，而不是文件名的一部分。

一般说明

始终use strict; use warnings;位于脚本顶部，这有助于发现问题。

Answer 2

人们在Perl中使用听到文件的大问题是他们忘记了行尾的分号。

这里的文件分为两种。如果在here文档名称周围使用双引号（或无引号），它将插入变量等。

如果在Here Document名称周围使用单引号，则不会进行插值。仔细观察分号和引号的位置。

#! /usr/bin/env perl
#
use warnings;
use strict;
use feature qw(say);

my $foo = "The value of foo";
my $bar = "The value of bar";

my $heredoc =<<"END_HERE_1";
This is my first here document
and this will interpolate things
like $foo and $bar.

Heck, it even shows up correcty
in VIM.
END_HERE_1

say "$heredoc"; #All set

print  <<'END_HERE_2';
This is my first here document
and this will NOT interpolate things
like $foo and $bar.

Heck, it even shows up correcty
in VIM.
END_HERE_2

say "And that's all folks!";

Answer 3

如果你想要一个here-document，你可以使用：

#!/usr/bin/env perl
use strict;
use warnings;

print "img URL = ?    ";
chomp(my $img = <>);
print "filename = ?   ";
chomp(my $filename = <>);

# now write xml with inserted contents to a file:
open my $CARDFILE, ">>", $filename or die "Failed to open file $filename for writing";
my $type = "unregimented";
my $expansion = "contracted";
my $keyword = "lock";
my $color = "green";
my $linkcolor = "blue";
my $kickercolor = "red";
my $cost = '$0.00';
my $strength = "humungous";
my $health = "excellent";

print $CARDFILE <<EOF;
<card>\r
    <img>$img</img>\r
    <type>$type</type>\r
    <expansion>$expansion</expansion>\r
    <keyword>$keyword</keyword>\r
    <color>$color</color>\r
    <linkcolor>$linkcolor</linkcolor>\r
    <kickercolor>$kickercolor</kickercolor>\r
    <cost>$cost</cost>\r
    <strength>$strength</strength>\r
    <health>$health</health>\r
</card>\r
EOF

close $CARDFILE;

请注意压缩输入，数据现在垂直排列 - 但是，运行Perl脚本几次，我宁愿从命令行参数获取数据而不是提示它。

具有讽刺意味的是，如果使用here文档，则无法使用输出记录分隔符指定行结尾。没有做任何特别的事情，你可以设置：

$\ = "\r\n";

并且每个print输出将以CRLF结束。（$\的默认值为undef，因此默认情况下不会将任何内容打印为行结束。）或者，您可以使用以下代码使代码更易于理解：

use English '-no_match_vars';

$ORS = "\r\n";

例如：

#!/usr/bin/env perl
use strict;
use warnings;
use English '-no_match_vars';

print "img URL = ?    ";
my $img = <>;
chomp($img);
print "filename = ?    ";
my $filename = <>;
chomp($filename);

# now write xml with inserted contents to a file:
open my $CARDFILE, ">>", $filename or die "Failed to open file $filename for writing";
my $type = "unregimented";
my $expansion = "contracted";
my $keyword = "lock";
my $color = "green";
my $linkcolor = "blue";
my $kickercolor = "red";
my $cost = '$0.00';
my $strength = "humungous";
my $health = "excellent";

$ORS = "\r\n";

print $CARDFILE "<card>";
print $CARDFILE "    <img>$img</img>";
print $CARDFILE "    <type>$type</type>";
print $CARDFILE "    <expansion>$expansion</expansion>";
print $CARDFILE "    <keyword>$keyword</keyword>";
print $CARDFILE "    <color>$color</color>";
print $CARDFILE "    <linkcolor>$linkcolor</linkcolor>";
print $CARDFILE "    <kickercolor>$kickercolor</kickercolor>";
print $CARDFILE "    <cost>$cost</cost>";
print $CARDFILE "    <strength>$strength</strength>";
print $CARDFILE "    <health>$health</health>";
print $CARDFILE "</card>";

close $CARDFILE;

Answer 4

你可以做到

print CARDFILE qq{<card> 
<img>$img</img>
<type>$type</type>};

等等。 qq告诉perl插入字符串，就像做“多行字符串”

一样

如何使用“here-doc”将行打印到文件？

4 个答案:

读一行

在这里，文档

印刷品

打开文件句柄

一般说明