Question

在我的xml文件中，元素不是常量，比如说我的文件是

<alpha>
  <a>...</a>
  <b>...</b>
  <c>...</c>
</alpha>
<alpha>
  <a>...</a>
  <c>...</c>
</alpha>
<alpha>
  <a>...</a>
  <b>...</b>
</alpha>
<alpha>
  <a>...</a>
  <b>...</b>
  <c>...</c>
</alpha>

我的意思是说我希望通过在集合中创建非现有元素来维护我的xml文件中的所有元素，并且如果使用xslt存在任何元素，则应该跳过。 PLS。帮我解决这个问题。

想要OutPut如下所示，通过在xslt中创建，值为0的非现有元素。

**

<alpha>
      <a>...</a>
      <b>...</b>
      <c>...</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>0</b>
      <c>...</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>...</b>
      <c>0</c>
    </alpha>
    <alpha>
      <a>...</a>
      <b>...</b>
      <c>...</c>
    </alpha>

**

Answer 1

XSLT 2.0

    <xsl:template match="a|b|c">
        <xsl:copy-of select="."/>
    </xsl:template>
    <xsl:template match="alpha">
        <xsl:variable name="alpha" select="."/>
        <xsl:variable name="forced">
            <forced>
                <a>0</a>
                <b>0</b>
                <c>0</c>
            </forced>
        </xsl:variable>
        <xsl:copy>
            <xsl:for-each select="$forced/forced/*">
                <xsl:variable name="current" select="name()"/>
                <xsl:choose>
                    <xsl:when test="exists($alpha/*[name() = $current])">
                        <xsl:apply-templates select="$alpha/*[name() = $current]"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <xsl:apply-templates select="$forced/forced/*[name() = $current]"/>
                    </xsl:otherwise>
                </xsl:choose>
            </xsl:for-each>
        </xsl:copy>
    </xsl:template>

XSLT 1.0

<xsl:template match="/root">
    <root>
        <xsl:for-each select="alpha">
                <alpha>
                <xsl:choose>
                    <xsl:when test="a">
                        <xsl:copy-of select="a"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <a>0</a>
                    </xsl:otherwise>
                </xsl:choose>
                <xsl:choose>
                    <xsl:when test="b">
                        <xsl:copy-of select="b"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <b>0</b>
                    </xsl:otherwise>
                </xsl:choose>
                <xsl:choose>
                    <xsl:when test="c">
                        <xsl:copy-of select="c"/>
                    </xsl:when>
                    <xsl:otherwise>
                        <c>0</c>
                    </xsl:otherwise>
                </xsl:choose>
                </alpha>
            </xsl:for-each>
    </root>
</xsl:template>

Answer 2

一个简单的，略微修改的身份转换可以做到这一点：

<xsl:stylesheet 
  version="1.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
>
  <xsl:template match="node() | @*">
    <xsl:copy>
      <xsl:apply-templates select="node() | @*" />
      <xsl:if test="self::alpha">
        <xsl:if test="not(a)"><a>0</a></xsl:if>
        <xsl:if test="not(b)"><b>0</b></xsl:if>
        <xsl:if test="not(c)"><c>0</c></xsl:if>
      </xsl:if>
    </xsl:copy>
  </xsl:template>
</xsl:stylesheet>

请注意，上述内容并未按此特定顺序创建a，b，c元素（因为我认为这不是必需的）。它只是确保它们中的所有三个都在那里，并按原样复制其余的输入。

维护xml文件中的所有xml元素

2 个答案: