Question

给定一个输入流我想以字节数组（块）的形式创建一个懒惰的数据序列。这是我的尝试：

(defn- read-or-nil [stream]
  (let [buf (byte-array 2)]
    (when-not (= -1 (.read stream buf))
      buf)))

(defn byte-chunk-seq [stream]
  (cons (read-or-nil stream) (lazy-seq (byte-chunk-seq stream))))

(with-open [rdr (java.io.FileInputStream. "/tmp/wut")]                                                                                                                                                                                         
  (take 2 (byte-chunk-seq rdr)))

在上一个语句中，我正在测试代码，我得到了一个：

IOException Stream Closed java.io.FileInputStream.readBytes（FileInputStream.java：-2）。

如果我将语句更改为take 1，那么它会返回正常，但这对我没什么帮助。有没有人有任何想法为什么这不起作用？

Answer 1

有几个问题。

首先，你的懒惰序列并不完全正确。函数的整个主体应该包含在lazy-seq中，它应该传入cons继续序列，或者nil来终止它。

(defn byte-chunk-seq [stream]
  (lazy-seq (if-let [buf (read-or-nil stream)]
              (cons buf (byte-chunk-seq stream))
              nil)))

其次，take也很懒惰。因此，在with-open关闭流之后才会实现延迟序列。您可以通过在延迟序列周围包裹doall以在流关闭之前实现它来避免此错误。

(with-open [rdr (java.io.FileInputStream. "/tmp/wut")]
  (doall (take 2 (byte-chunk-seq rdr))))

Clojure：从输入流创建一个懒惰的字节块序列

1 个答案: