相同x坐标上的两个数据点重叠

Question

我开始记录我跑步的日子和距离。我喜欢使用框来绘制这个，以便了解我最近的活动情况。

当我添加昨天的数据时，我今天遇到了一个问题。

从05/04/13可以看出，有两次运行，图表显示了同一天的两个方框（最左边的方框）。我喜欢这种行为。 06/26/13我又跑了两次，但这次情节只显示了一个（最右边的方框）。经过一段时间的游戏，我意识到这是因为在05/04，较大的数字（在第2列）是第一个，因此较小的数字会在它上面绘制。 06/26则相反，结果只能看到当天较大的数字。

有没有办法在不改变我的数据文件的情况下解决这个问题？

如果可以在绘图脚本中执行，我就不必看我如何将数据输入到我的文件中。

---

以下是数据：

05/04/13   1.59 
05/04/13   0.81 
05/05/13   1.56 
05/06/13   1.90 
05/08/13   2.77 
05/11/13   2.19 
05/12/13   0.93 
05/14/13   2.50 
05/15/13   1.04 
05/16/13   1.66 
06/02/13   4.02 
06/03/13   1.80 
06/04/13   1.04 
06/05/13   0.93 
06/12/13   1.18 
06/15/13   1.78 
06/16/13   1.26 
06/19/13   0.86 
06/21/13   0.93 
06/26/13   1.05 
06/26/13   1.39 

剧本：

set terminal x11 nopersist size 1200,645

unset mouse
unset key
unset label
unset grid

set boxwidth 86400 absolute
set style fill   solid 1.00 border lt -1
set bmargin at screen 0.08

set xdata time
set timefmt x "%m/%d/%y"
set format x "%b %d"
set xtics 86400 nomirror rotate by -90
set mxtics 0
set xrange [ "05/01/13" : "06/30/13" ] noreverse nowriteback

set ylabel "Distance" 
set ylabel textcolor lt -1 rotate by -270
set yrange [ 0.00000 : 4.50000 ] noreverse nowriteback

plot "/Users/user/Dropbox/nvalt/walks.txt" using 1:2 with boxes lt rgb "#777777"

情节图片：

Answer 1

对于这种类型的文件，日期的顺序并不重要，但正如您所提到的，数据的排序很重要。只需更换

，我就能获得所需的输出

plot "/Users/user/Dropbox/nvalt/walks.txt" using 1:2 with boxes lt rgb "#777777"

通过

plot "<sort -r /Users/user/Dropbox/nvalt/walks.txt" using 1:2 with boxes lt rgb "#777777"

这同样适用于同一日期的两个以上数据点。