Question

使用命令行和ImageMagic第一次摆弄后，我能够做到以下几点：

c:\test\paper.pdf contains a pdf file
c:\test>convert paper.pdf output-%d.tiff

pdf文件包含五个页面，输出是预期的5个tiff文件:-)现在我想在c:\test中放入多个文件并循环遍历它们，根据原始文件创建页面文件名。因此，请假设c:\test中的以下文件：

paper.pdf     (5 pages)
example.pdf   (2 pages)
new.pdf       (1 page)

批处理脚本的输出应该是c:\test\tiffs\文件夹中的8个tiff文件：

paper-0.tiff paper-1.tiff paper-2.tiff paper-3.tiff paper-4.tiff
example-0.tiff example-1.tiff
new-0.tiff

我非常希望命令行返回将pdf转换为tiff所花费的时间：

c:\test>convert.bat
c:\test>This action took 120 seconds

我正在尝试编写这个批处理文件，但因为这是我的第一次尝试，我遇到了麻烦。我首先尝试遍历test文件夹并创建所有tiff（暂时离开该过程）：

for %%f in (C:\test\) do convert %%f.pdf %%f-%%d.tiff

我原本预计这会有效但却出错了：

C:\Users\Me>convert c:\test\c:\test\.pdf c:\test\c:\test\-%d.tiff convert.exe: 
unable to open image `c:\test\c:\test\.pdf': Invalid argument @ 
error/blob.c/OpenBlob/2646. convert.exe: no decode delegate for this image 
format `c:\test\c:\test\.pdf' @ error/constitute.c/ReadImage/552. convert.exe: 
no images defined `c:\test\c:\test\-%d.tiff' @ 
error/convert.c/ConvertImageCommand/3106.

我做错了什么？

Answer 1

时序

这是错误要做的工作之一（对于真实 - 可以用它来展示）与批处理/ CMD。我遇到的几乎所有编程语言都比CMD更好。

如果经过的时间超过任何一天的午夜，这个特定的（hackish）实现将不起作用，并且取决于您在语言环境中配置的日期，如果运行在下午1点之前开始，它可能会中断。并在1 P.M。

之后结束

@ECHO OFF
SETLOCAL ENABLEDELAYEDEXPANSION

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET START_TIME=%%t

:: Stuff that you're timing.

FOR /F "tokens=5 delims= " %%t IN ('^<NUL time') DO SET END_TIME=%%t

SET ELAPSED=
FOR /F "delims=:. tokens=1,2,3,4" %%a IN ("%START_TIME%") DO (
    FOR /F "delims=:. tokens=1,2,3,4" %%n IN ("%END_TIME%") DO (
        SET /A HOURS=%%n-%%a
        SET /A MINUTES=%%o-%%b
        SET /A SECONDS=%%p-%%c
        SET /A HUND=%%q-%%d

        SET /A TOTAL=!HOURS!*3600 + !MINUTES!*60 + !SECONDS!
        IF !HUND! LSS 0 (
            SET /A TOTAL=!TOTAL!-1
            SET /A HUND=!HUND!+100
        )
        IF !HUND! LSS 10 SET HUND=0!HUND!

        SET ELAPSED=!TOTAL!.!HUND!
    )
)

@ECHO.
@ECHO.
@ECHO This action took %ELAPSED% seconds.

ImageMagick的

我在convert命令中看到的问题是您没有告诉CMD要搜索的模式。听起来你想要*.pdf。这样做意味着您不需要在输入文件名的末尾附加“.pdf”，并且在指定输出文件名时需要删除扩展名。 %%~dpnf生成没有扩展名的文件的完整路径。

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "%%~dpnf-%%d.tiff"

编辑：要将PDF放在其他位置，请更改%%f替换：

FOR %%f IN (C:\temp\*.pdf) do convert "%%~f" "\path\to\tiffs\%%~nf-%%d.tiff"

更好的方法？

我想我至少应该插上一个插件，以正确的方式做到这一点。如果您不想以支持计时的语言（如Python）从脚本调用命令，则只需将系统时间检索为整数即可。这个策略将持续到大约2038年。我在这个例子中使用了Perl。

@ECHO OFF

FOR /F %%t IN ('perl -e "print(time());"') DO SET START_TIME=%%t

:: stuff to time

FOR /F %%t IN ('perl -e "print(time());"') DO SET END_TIME=%%t
SET /A ELAPSED=%END_TIME%-%START_TIME%
@ECHO This step took %ELAPSED% seconds.

如何使用ImageMagick批量转换pdf并对流程进行基准测试？

1 个答案:

时序

ImageMagick的

更好的方法？