Question

我有一个声明如下的数组哈希：

my %hash;
push @{ $hash{ $value1[$_] } }, [ $value1[$_], $value2[$_], $value3[$_], $value4[$_], $value5[$_] ] for 0 .. $#value1;

我希望能够使用以下方法检查每个键的值：

open KEYS, '>keys.txt' or die "Can't write to 'keys.txt'\n";

for my $key ( sort keys %hash ) {
    print KEYS "Key: $key contains the values: ";
    for my $value ( @{$hash{$value1}} ) {
        print KEYS "$value ";
    }   
    print KEYS "\n";
}
close(KEYS);

虽然我可以使用Data :: Dumper可视化键和关联值，但上面代码的输出为每个键提供了内存位置，而不是值。 E.g：

Key: 'Value1' contains the values: ARRAY(0x7fcd8645ba68)

即使我将相同数量的值推到每个数组上，每个键包含不同数量的值

我这样做的方式有问题吗？

Answer 1

首先，在你的内循环中，你有

for my $value ( @{$hash{$value1}} ) {
    print KEYS "$value ";
}

$value1到底是什么？我想你想用$key。始终use strict; use warnings收到有关未定义值和未声明变量的警告。

接下来，让我们来看看当我们做什么时会发生什么

my %hash;
push @{ $hash{ $value1[$_] } }, "(value$_)" for 0 .. $#value1;

相反，即我们只是将字符串推送到散列中的arrayref。然后，输出看起来有点像

Key: Value1 contains the values: (value0)
Key: Value2 contains the values: (value1)
Key: Value3 contains the values: (value2)

啊哈！无论我们如何推动该阵列都按原样打印出来。如果您按下[...]之类的匿名数组引用，则会获得该引用的字符串化：ARRAY(0x1234567)。

您可能想要该arrayref的内容。容易：只是取消引用它。

...;
print KEYS "[@$value] ";

或类似的东西。此处使用"[...]"只是为了对输出进行可视化分组。

样式说明：

请考虑使用词汇文件句柄3-arg open：

my $filename = "keys.txt";
open my $keys, "<", $filename or die "Can't open $filename: $!";

或使用自动错误处理：

use autodie;
open my $keys, "<", "keys.txt";

无论哪种方式，在错误消息中包含失败$!的原因通常很重要，或者它几乎无用。

根据您的口味，使用map和join代码可能会更优雅，而不是使用循环。我可能会把循环写成

use feature 'say';
for my $key ( sort keys %hash ) {
    say {$keys} "Key: $key contains the values: "
      . join " ", map { "[@$_]" } @{ $hash{$key} };
}

Answer 2

那是因为你正在推送一个arrayref而不是一个值列表。

比较

push @array, [ $foo ];

到

push @array, $foo;

两个@array都包含一个元素，但前者包含一个包含$foo的arrayref，而后一个只包含$foo。

如果你在第一个push论证后丢失了方括号，你就可以去了。

打印perl中数组哈希的值

2 个答案: