Question

我正在寻找与Excel中的“VLOOKUP”功能类似的SAS代码。

我有两张桌子： table_1有一个ID列，其中包含10行其他列。表_2有两列：ID和定义有50行。我想在table_1中定义一个新变量“Definition”，并从table_2中查找ID值。

除了合并，我还没有尝试过任何其他方法。但是merge会保留table_2中所有额外的40个变量，这不是我喜欢的。

谢谢，SE

Answer 1

最简单的方法是在keep声明中使用merge选项。

data result;
    merge table_1 (in=a) table_2 (in=b keep=id definition);
    by id;
    if a;
 run;

另一种意味着您不必对数据集进行排序的方法是使用proc sql。

proc sql;
    create table result as
    select a.*,
           b.definition
    from table_1 a
    left join table_2 b on a.id = b.id;
quit;

最后，如果table_2很小，则有哈希表选项：

data result;
    if _n_ = 1 then do;
        declare hash b(dataset:'table_2');
        b.definekey('id');
        b.definedata('definition');
        b.definedone();
        call missing(definition);
    end;
    set table_1;
    b.find();
run;

Answer 2

这是一个非常有用（通常非常快）的方法，专门用于1：1匹配，这是VLOOKUP所做的。您可以使用match-variable和lookup-result创建Format或Informat，并在master表中创建匹配变量put或input。

data class_income;
set sashelp.class(keep=name);
income =  ceil(12*ranuni(7));
run;


data for_format;
set class_income end=eof;
retain fmtname 'INCOMEI';
start=name;
label=income;
type='i'; *i=informat numeric, j=informat character, n=format numeric, c=format character;
output;
if eof then do;
 hlo='o'; *hlo contains some flags, o means OTHER for nonmatching records;
 start=' ';
 label=.;
 output;
end;
run;

proc format cntlin=for_format;
quit;

data class;
set sashelp.class;
income = input(name,INCOMEI.);
run;

SAS代码与Excel的“VLOOKUP”功能类似

2 个答案: