Question

我想使用SPARQL创建观察排名。假设我有：

@prefix : <http://example.org#> .

:A :value 60 .
:B :value 23 .
:C :value 89 .
:D :value 34 .

排名应该是:: C = 1（最高），：A = 2，：D = 3，：B = 4.到目前为止，我能够使用以下查询解决它：

prefix : <http://example.org#> 
prefix rdf: <http://www.w3.org/1999/02/22-rdf-syntax-ns#>

SELECT ?x ?v ?ranking { 
 ?x :value ?v .
 { SELECT (GROUP_CONCAT(?x;separator="") as ?ordered) {
    { SELECT ?x {
       ?x :value ?v .
      } ORDER BY DESC(?v)
    }
   }
 }
 BIND (str(?x) as ?xName)
 BIND (strbefore(?ordered,?xName) as ?before) 
 BIND ((strlen(?before) / strlen(?xName)) + 1 as ?ranking)
} ORDER BY ?ranking

但该查询仅在?x的URI具有相同长度时才有效。一个更好的解决方案是在PHP中使用类似于strpos的函数或在Java中使用isIndexOf，但据我所知，它们在SPARQL 1.1中不可用。有更简单的解决方案吗？

Answer 1

这样做的一种方法是将值的排名作为小于或等于它的值的数量。对于较大的数据集，这可能是低效的，因为对于每个值，它必须检查所有其他值。但它不需要字符串操作。

PREFIX : <http://example.org#>

SELECT ?x ?v (COUNT(*) as ?ranking) WHERE {
  ?x :value ?v .
  [] :value ?u .
  FILTER( ?v <= ?u )
}
GROUP BY ?x ?v
ORDER BY ?ranking

---------------------
| x  | v  | ranking |
=====================
| :C | 89 | 1       |
| :A | 60 | 2       |
| :D | 34 | 3       |
| :B | 23 | 4       |
---------------------

如何在SPARQL中对值进行排名？

1 个答案: