Question

我正在使用ant任务'junit'和'junitreport'来运行我的JUnit测试并在最后生成一个报告（=＆gt;“单元测试结果”）。

是否有一些简单的方法可以以某种方式扩展此输出以获取报告中显示的更多信息？例如，添加一个包含测试截屏链接的附加列。

我看过有人可以像EclipseTestRunner那样写一个自己的蚂蚁junit测试跑步者但这是一些努力。是否没有API来访问单位报告的元素？

Answer 1

junitreport任务使用XSLT从junit任务生成的XML文件生成报告。

您可以使用嵌套styledir元素的report属性指定自己的XSLT来自定义输出：

<!-- use reportstyle/junit-frames.xsl to produce the report -->
<report styledir="reportstyle" format="frames" todir="testreport"/>

为了自定义输出，一个选项是复制default XSLT并修改它。或者您可以寻找替代XSLT，它更容易为您的目的定制。

对于小的更改，最简单的方法是导入默认的XSLT并覆盖您需要自定义的模板。例如，要为每个测试添加一列，您需要覆盖生成表头的模板和生成表行的模板。下面，我刚刚复制了这些模板并对其进行了一些修改以添加一列（查找标有的两个添加项）。

<xsl:stylesheet version="1.0"
                xmlns:xsl="http://www.w3.org/1999/XSL/Transform">

  <!-- import the default stylesheet -->
  <xsl:import href="jar:file:lib/ant-junit.jar!/org/apache/tools/ant/taskdefs/optional/junit/xsl/junit-frames.xsl"/>

  <!-- override the template producing the test table header --> 
  <xsl:template name="testcase.test.header">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:if test="boolean($show.class)">
        <th>Class</th>
      </xsl:if>
      <th>Name</th>
      <th>Status</th>
      <th width="80%">Type</th>
      <th nowrap="nowrap">Time(s)</th>

      <!-- ADDED -->
      <th>Screenshot</th>

    </tr>
  </xsl:template>

  <!-- override the template producing a test table row -->
  <xsl:template match="testcase" mode="print.test">
    <xsl:param name="show.class" select="''"/>
    <tr valign="top">
      <xsl:attribute name="class">
        <xsl:choose>
          <xsl:when test="error">Error</xsl:when>
          <xsl:when test="failure">Failure</xsl:when>
          <xsl:otherwise>TableRowColor</xsl:otherwise>
        </xsl:choose>
      </xsl:attribute>
      <xsl:variable name="class.href">
        <xsl:value-of select="concat(translate(../@package,'.','/'), '/', ../@id, '_', ../@name, '.html')"/>
      </xsl:variable>
      <xsl:if test="boolean($show.class)">
        <td><a href="{$class.href}"><xsl:value-of select="../@name"/></a></td>
      </xsl:if>
      <td>
        <a name="{@name}"/>
        <xsl:choose>
          <xsl:when test="boolean($show.class)">
            <a href="{concat($class.href, '#', @name)}"><xsl:value-of select="@name"/></a>
          </xsl:when>
          <xsl:otherwise>
            <xsl:value-of select="@name"/>
          </xsl:otherwise>
        </xsl:choose>
      </td>
      <xsl:choose>
        <xsl:when test="failure">
          <td>Failure</td>
          <td><xsl:apply-templates select="failure"/></td>
        </xsl:when>
        <xsl:when test="error">
          <td>Error</td>
          <td><xsl:apply-templates select="error"/></td>
        </xsl:when>
        <xsl:otherwise>
          <td>Success</td>
          <td></td>
        </xsl:otherwise>
      </xsl:choose>
      <td>
        <xsl:call-template name="display-time">
          <xsl:with-param name="value" select="@time"/>
        </xsl:call-template>
      </td>

      <!-- ADDED -->
      <td>
        <a href="link/to/screenshot/for/test/{@name}">screenshot</a>
      </td>

    </tr>
  </xsl:template>

</xsl:stylesheet>

结果如下：

screenshot

Answer 2

此外，如果您不想替换主xsl文件，可以将xsl文件复制到项目根文件夹中，使用您的更改进行更新，最后编辑build.xml文件，添加 styledir 属性：

<report styledir="." format="noframes" todir="${junit.output.dir}"/>

Answer 3

Jukka非常棒。这是Jukka关于如何链接屏幕截图

的答案的扩展

  <!-- ADDED -->
  <td>
    <a href="link/to/screenshot/for/test/{@name}">screenshot</a>
  </td>

而不是Jukka的回答上面的代码片段，以下是您如何链接屏幕截图：

    <!-- Added screenshot link for failed tests -->
    <td>
        <xsl:variable name="class.name">
            <xsl:value-of select="translate(@classname,'.','/')"/>
        </xsl:variable>
        <xsl:variable name="junit.base">
            <xsl:call-template name="path"><xsl:with-param name="path" select="../@package"/></xsl:call-template>
        </xsl:variable>
    <xsl:choose>
        <xsl:when test="failure">
            <a href="{concat($junit.base,$class.name,'/',@name,'.png')}"><xsl:value-of select="@name"/></a>
        </xsl:when>
        <xsl:when test="error">
            <a href="{concat($junit.base,$class.name,'/',@name,'.png')}"><xsl:value-of select="@name"/></a>
        </xsl:when>
    </xsl:choose>
    </td>

生成junit报告后你需要做的就是 - 复制所有截图来自＆＃34; selenium / screenshots /＆＃34;目录在junit_report目录下。

以上代码仅为失败的测试添加链接。如果你想要它，那么相应地修改代码。

自定义JUnit报告？

3 个答案: