Question

我有这样的数据 -

<item>
    <name>Bob</name>
    <fav_food>pizza</fav_food>
    <key>{Salary}</key>
    <value>1000</value>
</item>

我希望我的输出看起来像这样 -

<item>
    <name>Bob</name>
    <fav_food>pizza</fav_food>
    <Salary>1000</Salary>
</item>

编辑，而不仅仅是一个值，如果我有其他标签只保证其中一个非空，那么我的变换有什么问题？我正在使用Sean的XSLT 1.0转换作为源。

输入 -

<item>
    <name>Bob</name>
    <fav_food>pizza</fav_food>
    <key>{Salary}</key>
    <value />
    <value2>1000</value2>
    <value3 />
</item>

期望的输出 -

<item>
    <name>Bob</name>
    <fav_food>pizza</fav_food>
    <Salary>1000</Salary>
</item>

我目前的转型 -

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />  

<xsl:template match="@*|node()">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()" />
 </xsl:copy>
</xsl:template>

<xsl:template match="key">
<xsl:element name="{substring-before(substring-after(.,'{'),'}')}"> 
    <xsl:choose>
        <xsl:when test="value != ''">
            <xsl:value-of select="following-sibling::value" />
        </xsl:when>
        <xsl:when test="value2 != ''">
            <xsl:value-of select="following-sibling::value2" />
        </xsl:when>
        <xsl:when test="value3 != ''">
            <xsl:value-of select="following-sibling::value3" />
        </xsl:when>
        </xsl:choose>
    </xsl:element> 
</xsl:template>
</xsl:stylesheet>

Answer 1

XSLT 1.0解决方案......

<xsl:stylesheet version="1.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />  

<xsl:template match="@*|node()">
 <xsl:copy>
  <xsl:apply-templates select="@*|node()" />
 </xsl:copy>
</xsl:template>      

<xsl:template match="value" />

<xsl:template match="key">
 <xsl:element name="{substring-before(substring-after(.,'{'),'}')}"> 
   <xsl:value-of select="following-sibling::value" /> 
 </xsl:element> 
</xsl:template>

</xsl:stylesheet>

更新

这里也是一个XSLT 2解决方案。这是未经测试的。

<xsl:stylesheet version="2.0"
  xmlns:xsl="http://www.w3.org/1999/XSL/Transform"
  xmlns:fn="http://www.w3.org/2005/xpath-functions">
<xsl:output indent="yes" omit-xml-declaration="yes" />
<xsl:strip-space elements="*" />  

<xsl:template match="element()">
  <xsl:copy>
    <xsl:apply-templates select="@*,node()"/>
   </xsl:copy>
</xsl:template>

<xsl:template match="attribute()|text()|comment()|processing-instruction()">
  <xsl:copy/>
</xsl:template>

<xsl:template match="value" />

<xsl:template match="key">
 <xsl:element name="{fn:replace(.,'^\{(.*)\}$','$1')}"> 
   <xsl:value-of select="following-sibling::value" /> 
 </xsl:element> 
</xsl:template>

</xsl:stylesheet>

使用XSLT进行XML Key / Value操作

1 个答案:

更新