Question

我在工作簿（评级）中有一个表（问题），在问题表的底部有一个按钮，它从评级工作簿中复制表2（引用）并将其粘贴到根据以下命名的新工作簿中报价编号然后保存。

以下是代码：

Sub GetQuote()
    Range("AK548").Select
    Selection.Copy
    Range("AK549").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

    Dim Output As Workbook
    Dim FileName As String

    Set Output = Workbooks.Add
    FileName = ThisWorkbook.Path & "\" & ThisWorkbook.Worksheets("Questions").Range("AK545").Value & ".xls"
    Output.SaveAs FileName

    Application.DisplayAlerts = False

    Output.Worksheets("Sheet1").Delete
    ThisWorkbook.Worksheets(2).Copy Before:=Output.Worksheets("Sheet2")
    Output.Worksheets(1).Name = "Sheet1"

    Application.DisplayAlerts = True
    Output.Protect Password:="12345"
    Output.Save
End Sub

现在，我打算删除现在存在于此新副本和报价表之间的链接，并仅保留值。我该怎么做？

我发现这段代码应删除现有的链接：

Dim Cell As Range, FirstAddress As String, Temp As String
    'delete all links from selected cells
    Application.ScreenUpdating = False
    With Selection
        Set Cell = .Find("=*!", LookIn:=xlFormulas, searchorder:=xlByRows, _
        LookAt:=xlPart, MatchCase:=True)
        On Error GoTo Finish
        FirstAddress = Cell.Address
        Do
            Temp = Cell
            Cell.ClearContents
            Cell = Temp
            Set Cell = .FindNext(Cell)
        Loop Until Cell Is Nothing Or Cell.Address = FirstAddress
    End With
Finish:

我所做的所有额外工作都是将此代码放在名称和复制工作表的代码下面，但这些代码不起作用？

那么现在我将如何组合这两段代码，以便复制所有内容并删除链接？

Answer 1

我的现有工作簿有外部链接，我需要从工作簿中删除然后重新保存它们。

这对我有用：

Sub BreakExternalLinks()
'PURPOSE: Breaks all external links that would show up in Excel's "Edit Links" Dialog Box
'SOURCE: www.TheSpreadsheetGuru.com/The-Code-Vault

Dim ExternalLinksArray As Variant
Dim wb As Workbook
Dim x As Long

Set wb = ActiveWorkbook

'Create an Array of all External Links stored in Workbook
  ExternalLinksArray = wb.LinkSources(Type:=xlLinkTypeExcelLinks)

'if the array is not empty the loop Through each External Link in ActiveWorkbook and Break it
 If IsEmpty(ExternalLinksArray) = False then
     For x = 1 To UBound(ExternalLinksArray )
        wb.BreakLink Name:=ExternalLinksArray (x), Type:=xlLinkTypeExcelLinks
      Next x
end if

End Sub

Answer 2

这段代码杀死了活动工作簿中的所有连接...道歉，但不记得我从哪里得到它。

    'Kill Connections
    If ActiveWorkbook.Connections.Count > 0 Then
        For i = 1 To ActiveWorkbook.Connections.Count
        ActiveWorkbook.Connections.Item(1).Delete
        Next i
    Else
    End If

使用您的代码进行测试，这似乎有效：

    Dim Output As Workbook
Dim FileName As String

Set Output = Workbooks.Add
FileName = ThisWorkbook.Path & "\" & ThisWorkbook.Worksheets("Questions").Range("A1").Value & ".xls"
Output.SaveAs FileName

Application.DisplayAlerts = False

Output.Worksheets("Sheet1").Delete
ThisWorkbook.Worksheets(2).Copy Before:=Output.Worksheets("Sheet2")
Output.Worksheets(1).Name = "Sheet1"

Output.Worksheets(1).Select
If ActiveWorkbook.Connections.Count > 0 Then
    For i = 1 To ActiveWorkbook.Connections.Count
    ActiveWorkbook.Connections.Item(1).Delete
    Next i
Else
End If

Application.DisplayAlerts = True
Output.Protect Password:="12345"
Output.Save

Answer 3

如果您不使用实际的副本，也许它会有所帮助。粘贴功能。如果您只需要单元格的值，请将宏更改为

Sub GetQuote()
    Range("AK548").Select
    Selection.Copy
    Range("AK549").Select
    Selection.PasteSpecial Paste:=xlPasteValues, Operation:=xlNone, SkipBlanks _
        :=False, Transpose:=False

    Dim Output As Workbook
    Dim FileName As String

    Set Output = Workbooks.Add
    FileName = ThisWorkbook.Path & "\" & ThisWorkbook.Worksheets("Questions").Range("AK545").Value & ".xls"
    Output.SaveAs FileName

    Application.DisplayAlerts = False
    Dim v, r As Long, c As Long
    With ThisWorkbook.Worksheets(2)
        r = .Cells.SpecialCells(xlCellTypeLastCell).Row
        c = .Cells.SpecialCells(xlCellTypeLastCell).Column
        v = .Range(.Cells(1, 1), .Cells(r, c))
    End With
    With Output.Worksheets(1)
        .Range(.Cells(1, 1), .Cells(r, c)) = v
    End With

    Application.DisplayAlerts = True
    Output.Protect Password:="12345"
    Output.Save
End Sub

这会将原始表的值复制到新的工作簿表，而不包含任何链接。

P.S。：不要混淆 ThisWorkbook 和 ActiveWorkbook 。 ThisWorkbook是宏所在的工作簿（但不一定是活动工作簿）。 ActiveWorkbook是您当时看到的工作簿。

如何从链接到另一个工作簿的工作簿中删除链接

3 个答案: