Question

我有以下函数用于遍历PDF文件目录，并为每个文件创建一个缩略图：

<cffunction name="createThumbnails" returntype="Void" output="false">
    <cfscript>
        //  CONSTANTs
        var _PDF_PATH = APPLICATION.PDFSource & "\PDFs";

        //  Set defaults for private variables
        var _qPDFDir = QueryNew("");
        var _documentId = 0;
        var _sourceFilePath = "";
        var _sku = "";
        var _tempImageFilePath = "";
    </cfscript>

    <!--- Retrieve a list of file names in the directory of unprocessed PDF files --->
    <cfdirectory
        action="list"
        directory="#_PDF_PATH#"
        name="_qPDFDir"
        filter="*.pdf"
        type="file"
        sort="datelastmodified DESC"
        listinfo="name" />

    <!--- Loop through the list of file names in the directory of unprocessed non-PDF files --->
    <cfloop query="_qPDFDir" endrow="500">
        <cfset _sourceFilePath = _PDF_PATH & "\" & name />

        <cfif FileExists(_sourceFilePath) AND IsPDFFile(_sourceFilePath)>
            <cftry>
                <cfpdf
                    action="thumbnail"
                    source="#_sourceFilePath#"
                    destination="#APPLICATION.TempDir#"
                    format="png"
                    scale="100"
                    resolution="high"
                    overwrite="true"
                    pages="1" />

                <cfcatch>
                    <cfscript>
                        FileMove(
                            _sourceFilePath,
                            _PDF_PATH & "\NonFunctioning\"
                            );
                    </cfscript>
               </cfcatch>
            </cftry>

            <cfscript>
                _documentId =
                    REQUEST.UDFLib.File.getFileNameWithoutExtension(name);
                _tempImageFilePath =
                        APPLICATION.TempDir
                    &   "\"
                    &   _documentId
                    &   "_page_1.png";

                if  (FileExists(_tempImageFilePath)) {
                    _sku = getSkuFromDocumentId(_documentId);

                    if  (Len(_sku)) {
                        CreateObject(
                            "component",
                            "cfc.products.Product"
                            ).setClientId(
                                getClientId()
                                ).setId(
                                    _sku
                                    ).createThumbnails(
                                        sourcePath = _tempImageFilePath,
                                        deleteSourceFile = true
                                        );

                        FileMove(
                            _sourceFilePath,
                            APPLICATION.ProcessedPDFDir
                            );
                    }
                }
            </cfscript>
        </cfif>
    </cfloop>

    <cfreturn />
</cffunction>

有些代码不是我想做的 - 即将文件移动到“NonFunctioning”目录，但业务规则要求它。

我想弄清楚的是，当这个函数运行时，如何避免耗尽内存？

使用endrow="500"，在处理了大约148个文件后，它发生了java.lang.OutOfMemoryError: GC overhead limit exceeded错误。

当我在任务管理器（Windows）中查看jrun.exe进程时，我可以看到内存增加和增加。

有什么方法可以提高这个功能的性能，防止内存被吃掉？

Answer 1

您正在循环中创建对象，每次创建对象时CF都将保留在内存中，直到页面完成运行，然后释放内存。

在循环外实例化对象，将其保存在变量中并重复使用循环内的对象。
不要在一次传递中处理所有文件（如史蒂夫所建议的）在块中处理，然后创建一个新请求（例如cfhttp）并再次调用您的处理页面，这将释放第一遍中使用的所有内存。

在ColdFusion 8中生成缩略图时如何避免使用内存？

1 个答案: