Question

这是一个非常奇怪的问题。我几乎整天都把它简化为一个可以完全展示问题的小型可执行脚本。

问题摘要：我正在使用XML::Twig从XML文件中提取数据片段，然后我将该数据片段放在另一段数据的中间，让我们称之为父数据。当我开始时，父数据在其开头具有这种奇怪的不可打印字符。它是供应商提供的数据，所以我无法控制它。我的问题是，在将数据片段粘贴到父数据的中间之后，最终产品除了最初开始的字符之外还有一个新不可打印的字符。这个新的不可打印字符不在父数据中，也不在子数据片段中。我不知道它来自何处，也不知道它是如何进入我的数据的。

我怀疑它是一个XML :: Twig错误，因为在while循环中从文件句柄读取一行时发生字符串损坏，但是当我删除XML时，我一直没有成功地重新创建我的问题::在我的脚本中使用Twig代码，因此我不得不将其保留。

这是我第一次体验我正在尝试处理的字符串中的不可打印字符。我需要做一些特别的事情而不是像普通的字符串那样对待它们吗？

我在Windows XP上使用ActiveState Perl 5.10.1和XML :: Twig 3.32（最新）和Eclipse 3.5.1 IDE。

这是一个演示此问题的脚本：

use strict; 
use warnings; 
use XML::Twig; 

my $FALSE = 0;
my $TRUE = 1;
my $name = 'KurtsProgram';
my $task = 'MainTask';
my $hidden_char = "\xBF";
my $data = $hidden_char . 
'(*********************************************
  Data-File-Header-Junk
**********************************************)

    PROGRAM MainProgram ()
    END_PROGRAM

    TASK SecondaryTask ()
    END_TASK

    TASK MainTask ()
        MainProgram;
    END_TASK
';
my $new_data = insertProgram( $name, $task, $data );

# test to see if results start out as expected
if ( $new_data =~ m/^\Q$hidden_char\E/ ) {
    print "SUCCESS\n";
}
else {
    print STDERR "ERROR: What happened?\n";
    print STDERR "ORIGINAL: \n$data\n";
    print STDERR "MODIFIED: \n$new_data\n";
}

sub insertProgram {
    my ( $local_name, $local_task, $local_data ) = @_;

    # get program section from XML template
    my $twig = new XML::Twig;
    $twig->parse( '<?xml version="1.0"?>
<TemplateSet>
    <PROGRAM>PROGRAM <Name>ProgramNameGoesHere</Name> ()
    END_PROGRAM</PROGRAM>
    <TASK>TASK <Name>TaskNameGoesHere</Name> ()
    END_TASK</TASK>
</TemplateSet>
' );   
    my $program = $twig->root->first_child('PROGRAM');

    # replace program name in XML template
    $program->first_child('Name')->set_text($local_name);
    my $insert = $program->text();

    # stick modified program into data
    if ( $local_data =~ s/(\s+PROGRAM\s+[^\s]+\s+\()/\n\n    $insert $1/ ) {
        # found it and inserted new program
    }
    else {
        # not found
        return;
    }

    # add program name to task list
    my $added_program_to_task = $FALSE;
    my $found_start = $FALSE;
    my $found_end = $FALSE;
    my $new_data = "";
    # open string as a filehandle for line by line processing
    my $filehandle;
    open( $filehandle, '<', \$local_data )
        or die("Can't open string as a filehandle: $!");
    while (defined (my $line = <$filehandle>)) {
        # look for start of our task
        if ( 
               ( !$found_start ) &&
               ( $line =~ m/\s+TASK\s+\Q$local_task\E\s+\(/ )
            ) {
            # found the task!
            $found_start = $TRUE;
        }

        # look for end of our task
        if (
                ( $found_start ) && ( !$found_end ) &&
                ( $line =~ m/\s+END_TASK/ )
            )
        {
            # found the end tag for the task section!
            $found_end = $TRUE;

            # add the program name to the bottom of the list
            $line = "        " . $local_name . ";\n" . $line;
            $added_program_to_task = $TRUE;
        }

        # compile new data from processed line or original line
        $new_data = $new_data . $line;
    }
    close($filehandle);

    if ($added_program_to_task) {
        # success
    }
    else {
        # unable to find task
        return;
    }

    return $new_data;
}

当我运行此脚本时，我得到以下输出：

ERROR: What happened?
ORIGINAL: 
¿(*********************************************
      Data-File-Header-Junk
    **********************************************)

        PROGRAM MainProgram ()
        END_PROGRAM

        TASK SecondaryTask ()
        END_TASK

        TASK MainTask ()
            MainProgram;
        END_TASK

MODIFIED: 
Â¿(*********************************************
      Data-File-Header-Junk
    **********************************************)

        PROGRAM KurtsProgram ()
        END_PROGRAM 

        PROGRAM MainProgram ()
        END_PROGRAM

        TASK SecondaryTask ()
        END_TASK

        TASK MainTask ()
            MainProgram;
            KurtsProgram;
        END_TASK

您可以在MODIFIED中的M下看到添加到数据前面的额外字符。

Answer 1

它对角色\xBF - ＆gt;进行了ISO-8859-1到UTF-8编码转换。 \xC2\xBF。

XML :: Twig将其所有输入转换为UTF-8（see here）。

您可以告诉Twig使用keep_encoding选项保留输入编码（另请参阅XML :: Twig FAQ：My XML documents/data are produced by tools that do not grok Unicode, will XML::Twig help me there?）。

但也许最好保留UTF-8，或者默默地放弃角色，具体取决于你将要用它做什么。

Answer 2

我无法理解你的代码，它仍然太复杂而无法快速调试，但可能问题与BOM（参见Unicode BOM FAQ）有关，在开始时会被忽略一个XML文档，但如果你把它复制到另一个文件的中间？因为xBF值而在这里猜测，这是UTF-8文档的BOM的一部分。

使用Win32 Perl中的XML :: Twig的字符串损坏和不可打印的字符

2 个答案: