Question

是否可以制作20％透明的TMemo或其他vcl组件？像TButton或TEdit？

在搜索解决方案时，我发现了这一点：

From Here，然后我想，如果我在窗体上绘制图像（OnPaint）然后将AlphaBlend设置为ON，我可以实现这种效果但是没有成功，当整个窗体是透明的时，主要的需要效果是不能实现的，没有备忘录背后的照片。

enter image description here

我想达到的效果:(它在photoshop中完成） enter image description here

这可能吗？如果是，怎么样？（我不会要求任何人提供完整的src代码，如果可能的话只是文章或小例子，或方向，不管我能理解的方式）

thnx注意。

我找到了解决方案，在带有图片背景的表单上创建了alphablended表单，然后在添加的表单上添加备忘录并将其与客户端对齐，而不是最好的方式，但它运行正常： enter image description here

procedure TForm1.Button1Click(Sender: TObject);
var
 MM : TMyMemo; frm : TForm;
begin
 frm := TForm.Create(Form1);
 frm.BorderStyle := bsNone;
 frm.AlphaBlend := true;
 frm.AlphaBlendValue := 150;
 frm.Left     := Form1.Left + 90;
 frm.Top      := Form1.Top + 90;
 frm.Width    := 300;
 frm.Height   := 300;
 frm.Position := poDesigned;
 frm.Visible := true;

 MM             := TMyMemo.Create(frm);
 MM.Parent      := frm;
 MM.BorderStyle := bsNone;
 MM.ParentColor := False;
 MM.Align       := alClient;
 MM.Color       := clBlack;
 MM.Font.Color  := clWhite;
 MM.Font.Name   := 'Sylfaen';
 MM.Font.Size   := 11;
 MM.Visible     := True;

 frme := True;
end;

但是还有另一个问题，当我按下备忘录时，背景形式失去焦点，当我设置新表格时＃39; Form1的父级，上面的问题解决但是透明效果消失了（窗口仍然是透明的但是你可以看到没有可见背景的bg窗口）我该如何解决这个问题呢？

Answer 1

我认为这个问题经常被问到（也许不在这里，但我以前见过很多次）。奇怪的是，答案几乎永远不会出现，尽管它存在，隐藏在讨论这个问题的所有人中间。也许这里的问题将有助于改善未来的搜索过程，仅仅因为它是stackoverflow： - ）

无论如何，这是我去年找到的答案（见下面的代码）。不是我的，但对我有用 - 链接到author。本质上，代码使用WM_ERASEBACKGROUND消息的自定义事件处理程序定义派生的richedit。

unit TransparentRichEdit;

{ Component made by Proger_XP | http://Proger.i-Forge.net }

interface

uses
  Windows, Messages, SysUtils, Classes, Controls, StdCtrls, ComCtrls, Graphics;

type
  TTransparentRichEdit = class (TRichEdit)
  protected
    FCanvas: TCanvas;
    FBackground: TPicture;

    procedure CreateWnd; override;
    procedure WMEraseBkgnd(var Message: TWMEraseBkgnd); message WM_ERASEBKGND;

    procedure SetBackground(const Value: TPicture);
  public
    constructor Create(AOwner: TComponent); override;
    destructor Destroy; override;
  published
    property Background: TPicture read FBackground write SetBackground;
  end;

procedure Register;

implementation

procedure Register;
begin
  RegisterComponents('Miscellaneous', [TTransparentRichEdit]);
end;

{ TTransparentRichEdit }

constructor TTransparentRichEdit.Create(AOwner: TComponent);
begin
  inherited;
  FCanvas := TCanvas.Create;
  FBackground := TPicture.Create;
end;

destructor TTransparentRichEdit.Destroy;
begin
  FBackground.Free;
  FCanvas.Free;
  inherited;
end;

procedure TTransparentRichEdit.CreateWnd;
begin
  inherited;
  SetWindowLong(Handle, GWL_EXSTYLE, GetWindowLong(Handle, GWL_EXSTYLE) or WS_EX_TRANSPARENT);
end;

procedure TTransparentRichEdit.WMEraseBkgnd(var Message: TWMEraseBkgnd);
var
  UpdateRect: TRect;
  Rgn: HRGN;
  ToBeErased: Boolean;
  Mem: TBitmap;
begin
  ToBeErased:= false;
  Mem := TBitmap.Create;
  try
    Mem.Width := ClientWidth;
    Mem.Height := ClientHeight;

    FCanvas.Handle := Message.DC;
    Message.Result := 1;

    if not GetUpdateRect(Handle, UpdateRect, ToBeErased) then
      UpdateRect := Rect(0, 0, ClientWidth, ClientHeight);
    with UpdateRect do
      Rgn := CreateRectRgn(Left, Top, Right, Bottom);
    SelectClipRgn(FCanvas.Handle, Rgn);

    FCanvas.Draw(0, 0, FBackground.Graphic);
  finally
    Mem.Free;
  end;
end;

 procedure TTransparentRichEdit.SetBackground(const Value: TPicture);
 begin
   FBackground.Assign(Value);
   Repaint;
 end;

 end.

VCL组件不透明度/透明度

1 个答案: