Question

所以我正在编写一个处理草图来测试一个随机地形发生器，用于我正在研究的焦土克隆。它似乎按预期工作，但有一个小问题。在代码中我生成了800个1像素宽的矩形，并预先将填充设置为棕色。矩形的组合应该是具有棕色污垢样颜色的固体块（77,0,0）。

但是，无论rgb填充值设置如何，组合都显示为黑色。我想这可能与每个矩形的边框是黑色有关？有谁知道这里发生了什么事吗？

final int w = 800;
final int h = 480;

void setup() {
  size(w, h);
  fill(0,128,255);
  rect(0,0,w,h);
  int t[] = terrain(w,h);
  fill(77,0,0);
  for(int i=0; i < w; i++){
    rect(i, h, 1, -1*t[i]);
  }
}

void draw() {

}

int[] terrain(int w, int h){

    width = w;
    height = h;

    //min and max bracket the freq's of the sin/cos series
    //The higher the max the hillier the environment
    int min = 1, max = 6;

    //allocating horizon for screen width
    int[] horizon = new int[width];
    double[] skyline =  new double[width];

    //ratio of amplitude of screen height to landscape variation
    double r = (int) 2.0/5.0;

    //number of terms to be used in sine/cosine series
    int n = 4;

    int[] f = new int[n*2];


    //calculating omegas for sine series
    for(int i = 0; i < n*2 ; i ++){
      f[i] = (int) random(max - min + 1) + min;
    }

    //amp is the amplitude of the series
    int amp =  (int) (r*height);

    for(int i = 0 ; i < width; i ++){
      skyline[i] = 0;

      for(int j = 0; j < n; j++){
        skyline[i] += ( sin( (f[j]*PI*i/height) ) +  cos(f[j+n]*PI*i/height) );
      }

      skyline[i] *= amp/(n*2);
      skyline[i] += (height/2);
      skyline[i] = (int)skyline[i];
      horizon[i] =  (int)skyline[i];
    }
    return horizon;
}

Answer 1

我认为它可能与每个矩形的边框是黑色有关吗？

我相信情况就是这样。在setup()函数中，我在绘制矩形之前添加了noStroke()函数。这会将黑色轮廓移除到矩形。由于每个矩形只有1个像素宽，因此使用此黑色笔划（默认情况下处于启用状态）会使每个矩形的颜色变为黑色，无论您之前尝试选择何种颜色。

这是一个更新的setup()函数 - 我现在看到一个红褐色的地形：

void setup() {
  size(w, h);
  fill(0, 128, 255);
  rect(0, 0, w, h);
  int t[] = terrain(w, h);
  fill(77, 0, 0);
  noStroke(); // here
  for (int i=0; i < w; i++) {
    rect(i, h, 1, -1*t[i]);
  }
}

为什么这些形状是错误的颜色？

1 个答案: