Question

首先，是的，这是我的Perl课程的家庭作业项目。我不是在寻找答案（尽管那会很好）。据我了解，我需要使用BFS和正则表达式来组织我的数据以供使用。我需要一些方向。我如何使用BFS？我是否使用大量堆栈并浏览堆栈中的每个项目？我应该使用巨型哈希表吗？有没有人解决过这个问题？你是怎么做的？我只是需要一些方向。这类似于BST吗？这可能不使用图形模块吗？这是否可以使用哈希值？

Answer 1

请参阅Graph。

#!/usr/bin/perl

use autodie;
use strict; use warnings;

use Graph;
use Graph::TransitiveClosure::Matrix;

my $dat = 'kevin-bacon.dat';

my $kbg = Graph->new(undirected => 1);

open my $kbf, '<', $dat;

my %movies;

while ( my $line = <$kbf> ) {
    last unless $line =~ /\S/;
    chomp $line;
    my ($u, $m, $v) = split /;/, $line;
    $kbg->add_edge($u, $v);
    $movies{"$u|$v"} = $movies{"$v|$u"} = $m;
}

my $tcm = Graph::TransitiveClosure::Matrix->new($kbg,
    path_length => 1,
    path_vertices => 1,
);

my ($u, $v) = ('Kevin Bacon', 'Yelena Maksimova');

if ( my $n = $tcm->path_length($u, $v) ) {
    printf "%d degrees of separation between %s and %s\n", $n, $u, $v;
}

my @path = $tcm->path_vertices($u, $v);

for my $i ( 0 .. @path - 2 ) {
    my ($u, $v) = @path[$i, $i + 1];
    print qq{$u - $v: $movies{"$u|$v"}\n};
}

使用Boost项目中的kevin-bacon.dat：

3 degrees of separation between Kevin Bacon and Yelena Maksimova
Kevin Bacon - Elisabeth Shue: Hollow Man (2000)
Elisabeth Shue - Lev Prygunov: Saint, The (1997)
Lev Prygunov - Yelena Maksimova: Bezottsovshchina (1976)

Answer 2

这不是答案，但它暗示了你的回答。

首先在图表中查找广度优先搜索的内容，最好能满足您的需求。

此外，如果您没有获得正则表达式，您可以考虑标记化问题并查看它。可能不需要。检查作业，看看你是否可以在某些信息中 slurp 。

Perl的六度凯文培根

2 个答案: