Question

我有一个初学者问题：

我有一个@key_table和许多@values_tables。我想创建一个哈希引用的@table，所以有一个表，每个元素指向哈希，其中的键和值来自开头提供的那两个表。

任何人都可以帮助我吗？

例如：

@keys = (Kate, Peter, John);
@value1 = (1, 2, 3);
@value2 = (a, b, c);

我想要一个指向的双元素表：

%hash1 = (Kate=>1, Peter=>2, John=>3);
%hash2 = (Kate=>a, Peter=>b, John=>c);

Answer 1

如果你只是想创建两个哈希，那很简单：

my ( %hash1, %hash2 );
@hash1{ @keys } = @value1;
@hash2{ @keys } = @value2;

这利用了散列slices。

但是，制作一堆数字卡在最后的新变量通常是错误的。如果您希望将这些信息放在一个结构中，则可以使用引用创建嵌套的哈希值。

Answer 2

使用散列片是使用键/值填充散列的最常用方法，

 @hash1{@keys} = @value1;
 @hash2{@keys} = @value2;

但是可以使用ie以其他（效率较低）的方式完成。 map，

my %hash1 = map { $keys[$_] => $value1[$_] } 0 .. $#keys;
my %hash2 = map { $keys[$_] => $value2[$_] } 0 .. $#keys;

甚至foreach

$hash1{ $keys[$_] } = $value1[$_] for 0 .. $#keys;
$hash2{ $keys[$_] } = $value2[$_] for 0 .. $#keys;

Answer 3

这是一个例子：

use strict;
use warnings;
use Data::Dump;

#Example data
my @key_table = qw/Kate Peter John/;
my @values_tables = (
   [qw/1 2 3/],
   [qw/a b c/]
);

my @table;
for my $vt(@values_tables) {
    my %temph;
    @temph{ @key_table } = @$vt;
    push @table, \%temph;
}

dd(@table);
#<--- prints:
#(
#  { John => 3, Kate => 1, Peter => 2 },
#  { John => "c", Kate => "a", Peter => "b" },
#)

Answer 4

这样做：

   use Data::Dumper;
use strict;

my @keys = ("Kate", "Peter", "John");
my @value1 = (1, 2, 3);
my @value2 = ("a", "b", "c");
my (%hash1,%hash2);


for my $i (0 .. $#keys){
    $hash1{$keys[$i]}=$value1[$i];
    $hash2{$keys[$i]}=$value2[$i];
}

print Dumper(\%hash1);

print Dumper(\%hash2);

这是输出：

$VAR1 = {
          'John' => 3,
          'Kate' => 1,
          'Peter' => 2
        };
$VAR1 = {
          'John' => 'c',
          'Kate' => 'a',
          'Peter' => 'b'
        };

在Perl中创建一个哈希

任何人都可以帮助我吗？

4 个答案: