Question

我一直在阅读来自CS61A (Spring 2011)的Berkeley Opencourseware课程和来自MIT 6.001的OCW课程。一个使用STk（称为stk-simply），另一个使用mit-scheme作为讲座的编程语言。

我刚刚使用Heron's method编写了一个简单的平方根过程。该文件保存为sqrt.scm

;; setting an accuracy or tolerance to deviation between the actual and the expected values
(define tolerance 0.001)

;; gives average of two numbers
(define (average x y)
  (/ (+ x y) 2))

;; gives the absolute values of any number
(define (abs x)
  (if (< x 0) (- x) x))

;; gives the square of a number
(define (square x) (* x x))

;; tests whether the guess is good enough by checking if the difference between square of the guess
;; and the number is tolerable
(define (good-enuf? guess x)
  (< (abs (- (square guess) x)) tolerance))

;; improves the guess by averaging guess the number divided by the guess
(define (improve guess x)
  (average (/ x guess) guess))

;;  when a tried guess does not pass the good-enuf test then the tries the improved guess
(define (try guess x)
  (if (good-enuf? guess x)
      guess
      (try (improve guess x) x)))

;; gives back square root of number by starting guess with 1 and then improving the guess until good-enuf
(define (sqr-root x)
  (try 1 x))

这在STk中运行良好。

sam@Panzer:~/code/src/scheme$ sudo stk-simply
[sudo] password for sam: 
Welcome to the STk interpreter version 4.0.1-ucb1.3.6 [Linux-2.6.16-1.2108_FC4-i686]
Copyright (c) 1993-1999 Erick Gallesio - I3S - CNRS / ESSI <eg@unice.fr>
Modifications by UCB EECS Instructional Support Group
Questions, comments, or bug reports to <inst@EECS.Berkeley.EDU>.
STk> (load "sqrt.scm")
okay
STk> (sqr-root 25)
5.00002317825395
STk>

但不是在计划中。

sam@Panzer:~/code/src/scheme$ sudo scheme
[sudo] password for sam: 
MIT/GNU Scheme running under GNU/Linux
Type `^C' (control-C) followed by `H' to obtain information about interrupts.

Copyright (C) 2011 Massachusetts Institute of Technology
This is free software; see the source for copying conditions. There is NO warranty; not even for MERCHANTABILITY or FITNESS FOR A PARTICULAR PURPOSE.

Image saved on Thursday October 27, 2011 at 7:44:21 PM
  Release 9.1 || Microcode 15.3 || Runtime 15.7 || SF 4.41 || LIAR/i386 4.118 || Edwin 3.116

1 ]=> (load "sqrt.scm")

;Loading "sqrt.scm"... done
;Value: sqr-root

1 ]=> (sqr-root 25)

;Value: 1853024483819137/370603178776909

1 ]=>

我检查了手册，但我找不到原因。谁能让我知道为什么会这样？或者我忽略了代码中的错误？我是计划和计划的初学者。 STK。

Answer 1

试试这个，现在代码应该在两个解释器中返回相同的结果（忽略微小的舍入差异）：

(define (sqr-root x)
  (exact->inexact (try 1 x)))

答案一直都是一样的，只是MIT Scheme默认生成一个精确的结果，而STk返回一个不精确的值。使用上面的代码，我们在执行计算后将结果转换为不精确的数字。或者，我们可以从头开始执行转换（可能会在此过程中失去一些精度）：

(define (sqr-root x)
  (try 1 (exact->inexact x)))

这quote解释了观察到的行为：

方案编号是精确的还是不精确的。如果数字被写为精确常数或仅使用精确操作从精确数字派生，则数字是精确的。如果数字是作为不精确的常量编写的，如果它是使用不精确的成分导出的，或者它是使用不精确的操作派生的，则数字是不精确的。因此，不精确是一个数字的传染性财产。

Answer 2

如果您在MIT Scheme中写过：

，您的答案看起来都是一样的

(sqr-root 25.)

因为'不精确'是'粘性'

代码在stk中工作 - 简单但不在mit方案中

2 个答案: