我发现这个“附加组件”名为“inno-web-browser”,由论坛用户在这里制作TLama,非常好的这个插件,可以完美打开网址,但我需要知道你是否有我监控点击次数,从而进行安装或其他事情,例如:
网址将是http://www.example.com/ads.php
这个文件“ads.php”将生成一个广告:这个广告将是一个共同的横幅(单个图像)的时间,它将花费时间在闪存中完成,到目前为止一直很好。
我想知道当NEXT页面iframe(ads.php)正在收费时它是否有锁定按钮,并且只有在用户点击广告(图像或闪光灯)后才会发布NEXT按钮。
你可以这样做吗?
答案 0 :(得分:2)
我为Web浏览器控件的BeforeNavigate2
事件添加了一个事件处理程序。现在,此新功能扩展了示例脚本。首先得到the most recent version
并使用如下代码。除非用户单击显示的StackOverflow站点的“用户”选项卡,否则它将使用浏览器禁用自定义页面上的“下一步”按钮。但是要非常小心这种禁用,因为并非所有用户都可以连接到互联网,而且这些用户会被安装程序困住:
[Setup]
AppName=Web Browser Project
AppVersion=1.0
DefaultDirName={pf}\Web Browser Project
[Files]
Source:"WebBrowser.dll"; Flags: dontcopy
[Code]
const
EVENT_BEFORE_NAVIGATE = 1;
var
CustomPage: TWizardPage;
type
TWebBrowserEventProc = procedure(EventCode: Integer; URL: WideString);
procedure CreateWebBrowser(ParentWnd: HWND; Left, Top, Width, Height: Integer;
CallbackProc: TWebBrowserEventProc);
external 'CreateWebBrowser@files:webbrowser.dll stdcall';
procedure DestroyWebBrowser;
external 'DestroyWebBrowser@files:webbrowser.dll stdcall';
procedure ShowWebBrowser(Visible: Boolean);
external 'ShowWebBrowser@files:webbrowser.dll stdcall';
procedure NavigateWebBrowser(URL: WideString);
external 'NavigateWebBrowser@files:webbrowser.dll stdcall';
procedure OnWebBrowserEvent(EventCode: Integer; URL: WideString);
begin
// this event will fire with the EVENT_BEFORE_NAVIGATE event code whenever
// you browse somewhere; this includes all iFrames and redirections, so for
// your case will be the best wait until your user navigate to the target of
// the ad (in this example unless user clicks the Users tab on StackOverflow)
if (EventCode = EVENT_BEFORE_NAVIGATE) and (URL = 'http://stackoverflow.com/users') then
WizardForm.NextButton.Enabled := True;
end;
procedure InitializeWizard;
begin
CustomPage := CreateCustomPage(wpWelcome, 'Web Browser Page',
'This page contains web browser');
CreateWebBrowser(WizardForm.InnerPage.Handle, 0, WizardForm.Bevel1.Top,
WizardForm.InnerPage.ClientWidth, WizardForm.InnerPage.ClientHeight - WizardForm.Bevel1.Top,
@OnWebBrowserEvent);
// I've been getting JSON error; so please ignore it, it's not my fault
NavigateWebBrowser('http://stackoverflow.com/');
end;
procedure DeinitializeSetup;
begin
DestroyWebBrowser;
end;
procedure CurPageChanged(CurPageID: Integer);
begin
ShowWebBrowser(CurPageID = CustomPage.ID);
if CurPageID = CustomPage.ID then
WizardForm.NextButton.Enabled := False;
end;