Question

我使用以下内容将文本文件中的文本插入TMemo。

procedure TForm1.Button1Click(Sender: TObject);
  var
  SL: TStringList;
begin
  SL := TStringList.Create;
  try
    SL.LoadFromFile('c:\testimeng\keyfil.txt');
    Memo1.Lines.Assign(SL);
  finally
    SL.Free;
  end;
end;

我想知道的是当我选择特定的行号时，如何根据行号添加一行到TMemo。

示例输出：

在此期间，他在学校生活的学术，体育和文化领域中脱颖而出。

在此期间，他在学校生活的学术和体育领域中脱颖而出。

在此期间，他在学校生活的学术和文化领域中脱颖而出。

在此期间，他在学校生活的学术方面表现出色。

在此期间，他在学校生活的体育和文化方面都表现出色。

任何帮助表示感谢。

Answer 1

当您指定TStringList中的哪个项目（索引或行号）时，我认为您要求将TMemo中的一行放入TStringList。如果是这种情况，您可以使用以下内容：

Memo1.Lines.Add(SL[Index]);

因此，如果keyfile.txt中的第一行是

During this time he has distinguished himself in the academic, sporting and cultural spheres of school life.

你会用

Memo1.Lines.Add(SL[0]);  // Desired line number - 1

好的，在您对您的问题发表评论后，我想我知道您想要做什么。这是一种方法：

在表单上删除TListBox，TButton和TMemo。我安排了我左边的ListBox，旁边的按钮（右上角），然后是按钮右边的备忘录。

在FormCreate事件中，使用您的文本文件填充TListBox并清除现有的备忘录内容：

procedure TForm1.FormCreate(Sender: TObject);
begin
  Memo1.Clear;
  ListBox1.Items.LoadFromFile('c:\testimeng\keyfil.txt');
end;

双击按钮添加OnClick处理程序：

procedure TForm1.Button1Click(Sender: TObject);
var
  s: string;
begin
  // If there's an item selected in the listbox...
  if ListBox1.ItemIndex <> -1 then
  begin
    // Get the selected item
    s := ListBox1.Items[ListBox1.ItemIndex];
    // See if it's already in the memo. If it's not, add it at the end.
    if Memo1.Lines.IndexOf(s) = -1 then
      Memo1.Lines.Add(s);
  end;
end;

现在运行应用程序。单击列表框中的项目，然后单击按钮。如果该项目尚未出现在备忘录中，则会将其添加为新的最后一行。如果它已经存在，则不会添加（以防止重复）。

如果您想将它添加到当前最后一行的末尾（可能是扩展段落），那么您可以这样做：

// Add selected sentence to the end of the last line of the memo, 
// separating it with a space from the content that's there.
Memo1.Lines[Memo1.Lines.Count - 1] := Memo1.Lines[Memo1.Lines.Count - 1] + #32 + s;

所以，现在应该很清楚，要添加到特定行的末尾，您只需抓取已经存在的内容在那里并添加它。例如，如果用户将3键入TEdit：

procedure TForm1.FormCreate(Sender: TObject);
begin
  SL := TStringList.Create;
  SL.LoadFromFile('c:\testimeng\keyfil.txt');
end;

procedure TForm1.ButtonAddTextClick(Sender: TObject);
var
  TheLine: Integer;
begin
  // SL is the TStringList from the FormCreate code above
  TheLine := StrToIntDef(Edit1.Text, -1);
  if (TheLine > -1) and (TheLine < Memo1.Lines.Count) then
    if TheLine < SL.Count then
      Memo1.Lines[TheLine] := Memo1.Lines[TheLine] + SL[TheLine];
end;

Answer 2

使用字符串鼠标写一个特定的行单击TMemo

Procedure TForm1.Button1Click(Sender: TObject);
Var SL: TStringList;
    LineNumber : Integer;
Begin
  LineNumber := Memo1.Perform(EM_LINEFROMCHAR, Memo1.SelStart, 0);
  Memo1.SelStart := Memo1.Perform(EM_LINEINDEX, LineNumber, 0);
  Memo1.SelLength := Length(Memo1.Lines[LineNumber]) ; 
  Memo1.SetFocus;

  SL := TStringList.Create;
  try
    SL.LoadFromFile('c:\testimeng\keyfil.txt');
    Memo1.SelText := SL.Strings[0];
  finally
    SL.Free;
  end;
End;

根据行号在tmemo中写入特定行

2 个答案:

使用字符串鼠标写一个特定的行单击TMemo