Question

如何创建相同的XML工作表，但删除了每个属性的前导和尾随空格？（使用XSLT 2.0）

从这里开始：

<node id="DSN ">
    <event id=" 2190 ">
        <attribute key=" Teardown"/>
        <attribute key="Resource "/>
    </event>
</node>

对此：

<node id="DSN">
    <event id="2190">
        <attribute key="Teardown"/>
        <attribute key="Resource"/>
    </event>
</node>

~~我想我更喜欢使用normalize-space()函数，但无论如何都行。~~

Answer 1

normalize-space()不仅会删除前导和尾随空格，而且还会安装一个空格字符来代替任何连续的空白字符序列。

正则表达式可用于处理前导空格和尾随空格：

<xsl:stylesheet xmlns:xsl="http://www.w3.org/1999/XSL/Transform" version="2.0">

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates select="@*|node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:attribute name="{local-name()}" namespace="{namespace-uri()}">
      <xsl:value-of select="replace(., '^\s+|\s+$', '')"/>
    </xsl:attribute>
  </xsl:template>

</xsl:stylesheet>

Answer 2

这应该这样做：

<xsl:stylesheet version="2.0" xmlns:xsl="http://www.w3.org/1999/XSL/Transform">
  <xsl:output method="xml" indent="yes" omit-xml-declaration="yes"/>

  <xsl:template match="node()">
    <xsl:copy>
      <xsl:apply-templates select="@* | node()"/>
    </xsl:copy>
  </xsl:template>

  <xsl:template match="@*">
    <xsl:attribute name="{name()}">
      <xsl:value-of select="normalize-space()"/>
    </xsl:attribute>
  </xsl:template>
</xsl:stylesheet>

这也是XSLT 1.0兼容的。

在样本输入上运行时，结果为：

<node id="DSN">
  <event id="2190">
    <attribute key="Teardown" />
    <attribute key="Resource" />
  </event>
</node>

这里需要注意的一点是，normalize-space()会将属性值中的任何空格转换为单个空格，因此：

<element attr="   this    is an
                   attribute   " />

将改为：

<element attr="this is an attribute" />

如果您需要将空格保持在该值内，请参阅Gunther的答案。

XSLT删除所有属性的前导和尾随空格

2 个答案: