Question

我有xml：

<graph>
<node id="a" />
<node id="b" />
<node id="c" />
<node id="d" />

<link from="a" id="link1" to="b"/>
<link from="b" id="link2" to="d"/>
<link from="d" id="link3" to="c"/>

</graph>

我想通过xslt将其转换为下一个xml：

<graph>
<node id="a">
    <link id="link1" to="b">
</node>
<node id="b">
    <link id="link2" to="d">
</node><node id="c">
<node id="c"/>
<node id="d">
    <link id="link3" to="c">
</node>
</graph>

我写了xslt，其中包括下一部分：

<xsl:template match="//node">
    <xsl:element name="link">
            <xsl:attribute name="to">
                <xsl:value-of select="//link[@from = self::node()/@id]/@to"></xsl:value-of>
            </xsl:attribute>
    <xsl:apply-templates />     
    </xsl:element>


</xsl:template>

但这不起作用。我做错了什么？

Answer 1

您的XSLT只会创建link个元素，但您必须以某种方式创建graph和node个元素。此外，谓词中的self::node()不能按预期工作。请改用current()功能。

要解决您的任务，最好先从身份转换开始，然后为需要特殊处理的节点添加模板。这是一个例子：

<!-- Identity transform -->
<xsl:template match="node() | @*">
    <xsl:copy>
        <xsl:apply-templates select="node() | @*"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="graph">
    <xsl:copy>
        <!-- Only process node children -->
        <xsl:apply-templates select="node"/>
    </xsl:copy>
</xsl:template>

<xsl:template match="node">
    <xsl:copy>
        <!-- Also process matching links -->
        <xsl:apply-templates select="@* | //link[@from = current()/@id]"/>
    </xsl:copy>
</xsl:template>

<!-- Don't copy @from attribute of links -->
<xsl:template match="link/@from"/>

添加属性，该值是另一个元素的属性值

1 个答案: