Question

我知道正则表达式可用于编写检查括号的开始和结束符号对的检查器：

例如。 a.[b.[c.d]].e屈服值a，[b.[c.d]]和e

如何编写一个正则表达式，可以找出符号相同的开始和结束括号

例如。 a.|b.|c.d||.e会产生值a，|b.|c.d||和e

更新

感谢所有评论。我必须提出一些问题的背景。我基本上想模仿javascript语法

a.hello is a["hello"] or a.hello
a.|hello| is a[hello]
a.|b.c.|d.e||.f.|g| is a[b.c[d.e]].f[g]

所以我想做的是将符号分解为：

 [`a`, `|b.c.|d.e||`, `f`, `|g|`]

然后如果它们是管道引用则重复它们

我在这里没有管道的语法实现：

https://github.com/zcaudate/purnam

我真的希望不使用解析器主要是因为我不知道怎么做，我不认为它证明了必要的复杂性。但如果正则表达式无法削减它，我可能不得不这样做。

Answer 1

感谢@ m.buettner和@rafal，这是我在clojure中的代码：

有一个normal-mode和pipe-mode。遵循m.buettner的描述：

助手：

(defn conj-if-str [arr s]
  (if (empty? s) arr
      (conj arr s)))

(defmacro case-let [[var bound] & body]
  `(let [~var ~bound]
     (case ~var ~@body)))

管道模式：

(declare split-dotted) ;; normal mode declaration

(defn split-dotted-pipe   ;; pipe mode
  ([output current ss] (split-dotted-pipe output current ss 0))
  ([output current ss level]
      (case-let
       [ch (first ss)]
       nil (throw (Exception. "Cannot have an unpaired pipe"))
       \|  (case level
             0 (trampoline split-dotted
                           (conj output (str current "|"))
                           "" (next ss))
             (recur output (str current "|") (next ss) (dec level)))
       \.  (case-let
            [nch (second ss)]
            nil (throw (Exception. "Incomplete dotted symbol"))
            \|  (recur output (str current ".|") (nnext ss) (inc level))
            (recur output (str current "." nch) (nnext ss) level))
       (recur output (str current ch) (next ss) level))))

普通模式：

(defn split-dotted
  ([ss]
     (split-dotted [] "" ss))
  ([output current ss]
     (case-let
      [ch (first ss)]
       nil (conj-if-str output current)
       \.  (case-let
            [nch (second ss)]
            nil (throw (Exception. "Cannot have . at the end of a dotted symbol"))
            \|  (trampoline split-dotted-pipe
                            (conj-if-str output current) "|" (nnext ss))
            (recur (conj-if-str output current) (str nch) (nnext ss)))
       \|  (throw (Exception. "Cannot have | during split mode"))
       (recur output (str current ch) (next ss)))))

试验：

(fact "split-dotted"
  (js/split-dotted "a") => ["a"]
  (js/split-dotted "a.b") => ["a" "b"]
  (js/split-dotted "a.b.c") => ["a" "b" "c"]
  (js/split-dotted "a.||") => ["a" "||"]
  (js/split-dotted "a.|b|.c") => ["a" "|b|" "c"]
  (js/split-dotted "a.|b|.|c|") => ["a" "|b|" "|c|"]
  (js/split-dotted "a.|b.c|.|d|") => ["a" "|b.c|" "|d|"]
  (js/split-dotted "a.|b.|c||.|d|") => ["a" "|b.|c||" "|d|"]
  (js/split-dotted "a.|b.|c||.|d|") => ["a" "|b.|c||" "|d|"]
  (js/split-dotted "a.|b.|c.d.|e|||.|d|") => ["a" "|b.|c.d.|e|||" "|d|"])

(fact "split-dotted exceptions"
  (js/split-dotted "|a|") => (throws Exception)
  (js/split-dotted "a.") => (throws Exception)
  (js/split-dotted "a.|||") => (throws Exception)
  (js/split-dotted "a.|b.||") => (throws Exception))

一个正则表达式，可以拆分具有相同嵌套括号的字符串

更新

1 个答案:

助手：

管道模式：

普通模式：

试验：