Question

我正在清理和整理我的NAS文件夹。

但是，我有超过1800+文件夹的文件夹，我需要将其拆分为18个文件夹，每个文件夹最多包含100个文件夹。它们被移动到的文件夹的名称是无关紧要的，但在顶层应该是顺序的。应该移动所有文件夹内容。

此外，我需要一个批处理文件，它也可以反转这个。

需要这样做的原因是我用来索引和整理文件夹和文件夹内容的程序无法轻松处理超过100个文件夹的文件夹。

我已经尝试过了，但最终还是完全没法了。

Answer 1

这样的东西？

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /s /a:d "%source%*"') do (
  SET str=%%f
  SET str=!str:%source%=!
  MKDIR %destination%dir!dcount!\!str!
  COPY %%f %destination%dir!dcount!\!str! 1> NUL
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

显然需要更改源和目标，并且没有尝试从错误中进行健全性检查或失败......

编辑：

第一个版本递归地下降所有子目录并将它们移动到新结构中 - 基本上破坏了它们的内部嵌套和组织。第二个保留嵌套在源目录的直接子目录中的子目录的内部结构......随意选择。

@ECHO OFF

SET destination=c:\temp\
SET source=c:\windows\system32\
SET dcount=0
SET fcount=0
SETLOCAL ENABLEDELAYEDEXPANSION

MKDIR %destination%dir%dcount%


FOR /f "tokens=*" %%f in ('DIR /b /a:d "%source%*"') do (
  MKDIR %destination%dir!dcount!\%%f
  XCOPY %source%%%f %destination%dir!dcount!\%%f /e /y 
  SET /a fcount=!fcount!+1
  IF !fcount! EQU 100 (
    SET fcount=0
    SET /a dcount=!dcount!+1
    MKDIR %destination%dir!dcount!
  )
)

ECHO DONE.

Answer 2

这适用于我的有限测试并创建UNDO.BAT以将文件夹还原到它们所在的位置。为自己测试一下，确保它能达到你想要的效果。

值num是每个顶级文件夹中所需的文件夹数

f用于创建保留文件夹 - 001,002,003等

在包含要移动的所有子目录的文件夹中启动它。

@echo off
setlocal enabledelayedexpansion
set num=100
set c=0
set f=1001
set folder=%f:~-3%
del undo.bat 2>nul
for /f "delims=" %%a in ('dir /a:d /o:n /b') do (
set /a c=c+1
   md !folder! 2>nul
   move "%%a" !folder!
   echo move "!folder!\%%a" "%cd%" ^& rd !folder! 2^>nul >>undo.bat
    if !c! EQU %num% (
      set c=0
      set /a f=f+1
      set folder=!f:~-3!
    )
)

Windows批处理 - 将x个文件夹+内容移动到另一个文件夹

2 个答案: