Question

我在Fortran 95中编写了一个基本算法来计算函数的梯度（代码中规定了一个例子），使用称为Richardson外推的过程增加了中心差异。

function f(n,x)
! The scalar multivariable function to be differentiated

integer :: n
real(kind = kind(1d0)) :: x(n), f

f = x(1)**5.d0 + cos(x(2)) + log(x(3)) - sqrt(x(4))

end function f
!=====!
!=====!
!=====!

program gradient
!==============================================================================!
! Calculates the gradient of the scalar function f at x=0using a finite        !
! difference approximation, with a low order Richardson extrapolation.         !
!==============================================================================!

parameter (n = 4, M = 25)
real(kind = kind(1d0)) :: x(n), xhup(n), xhdown(n), d(M), r(M), dfdxi, h0, h, gradf(n)

h0 = 1.d0
x  = 3.d0

! Loop through each component of the vector x and calculate the appropriate
! derivative
do i = 1,n
! Reset step size
h = h0

    ! Carry out M successive central difference approximations of the derivative
do j = 1,M
        xhup = x
        xhdown = x
        xhup(i) = xhup(i) + h
        xhdown(i) = xhdown(i) - h
        d(j) = ( f(n,xhup) - f(n,xhdown) ) / (2.d0*h)
    h = h / 2.d0
    end do

    r = 0.d0
    do k = 3,M      r(k) = ( 64.d0*d(k) - 20.d0*d(k-1) + d(k-2) ) / 45.d0
        if ( abs(r(k) - r(k-1)) < 0.0001d0 ) then
        dfdxi = r(k)
            exit
        end if
    end do

    gradf(i) = dfdxi
end do

! Print out the gradient
write(*,*) " "
write(*,*) " Grad(f(x)) = "
write(*,*) " "
do i = 1,n
    write(*,*) gradf(i)
end do

end program gradient

单精度运行良好，给我不错的效果。但是当我尝试更改为代码中显示的双精度时，在尝试编译声明赋值语句时出现错误

d(j) = ( f(n,xhup) - f(n,xhdown) ) / (2.d0*h)

正在产生类型不匹配real(4)/real(8)。我尝试了几种不同的双精度声明，在d0的代码中附加了每个适当的双精度常量，每次都得到相同的错误。关于函数f如何产生单个精度数，我有点难过。

Answer 1

问题是f在主程序中没有明确定义，因此隐含地假设它是单精度的，这是gfortran的类型real（4）。

我完全同意高性能标记的评论，你真的应该在所有的fortran代码中使用implicit none，以确保明确声明所有对象。这样，您就可以获得有关f未明确定义的更合适的错误消息。

另外，你可以考虑另外两件事：

在模块中定义您的功能并在主程序中导入该模块。最好只在模块中定义所有子例程/函数，以便在调用函数时编译器可以对参数的数量和类型进行额外检查。

你可以（再次在模块中）为精确度引入一个常量并在任何地方使用它，其中必须指定一个真实的类型。以下面的示例为例，仅更改行

integer, parameter :: dp = kind(1.0d0)

到

integer, parameter :: dp = kind(1.0)

您可以将所有实际变量从双精度更改为单精度。另请注意文字常量的_dp后缀，而不是d0后缀，后者会自动调整其精度。

module accuracy
  implicit none

  integer, parameter :: dp = kind(1.0d0)

end module accuracy


module myfunc
  use accuracy
  implicit none

contains

  function f(n,x)
    integer :: n
    real(dp) :: x(n), f
    f = 0.5_dp * x(1)**5 + cos(x(2)) + log(x(3)) - sqrt(x(4))
  end function f

end module myfunc


program gradient
  use myfunc
  implicit none

  real(dp) :: x(n), xhup(n), xhdown(n), d(M), r(M), dfdxi, h0, h, gradf(n)
  :

end program gradient

fortran中的数据类型不匹配

1 个答案: