Question

如何识别没有算术的Prolog中的A ^ n B ^ n语言以及任何A，B，其中A！= B？

已知A = a和B = b我们可以写

% For each 'a' save 'b' in a list, then check 
% whether constructed list is equal to the rest of input list

anbn(L) :- anbn(L, []). 

anbn(L, L). 

anbn([a|L],A) :- anbn(L, [b|A]).

对于任何A和B，我都在考虑以

开头的解决方案

anbn(L) :- anbn(L, []).

anbn([H|L],[]) :- anbn(L,[H]). % save an element

anbn([H|L], [H|A]) :- anbn(L, [H,H|A]). % make sure front elements are the same

所以第一个元素都是一样的，但是我没有看到一个优雅的方法来检查列表其余部分中的所有元素是否与前面的元素相同和不同。

我可以检查其余部分是否与存储的列表一样长，然后是否只包含第二个类型的元素，但我相信我的问题过于复杂，并且存在一个简短的解决方案。

Answer 1

使用明确的句子语法。

s(_, _) --> [].
s(A, B) --> [A], s(A, B), [B].

演示：

?- phrase(s(1, 2), X).
X = [] ;
X = [1, 2] ;
X = [1, 1, 2, 2] ;
X = [1, 1, 1, 2, 2, 2] .

Answer 2

编辑：回到原始解决方案，并坚持下去：

anbn(List) :- List = [] -> true; List = [A|Rest], a(Rest, A, 0).

a([A|Rest], A, N) :- !, a(Rest, A, s(N)).
a([B|Rest], _, N) :- b(Rest, B, N).

b([B|Rest], B, s(N)) :- b(Rest, B, N).
b([], _, 0).

它是迭代的，它不会创建选择点，很明显，如果列表的所有元素都是基础的，那么它是正确的。

Answer 3

DCG通常会对裸变量进行重新包装在翻译期间作为短语/ 3。这样一来就可以实现 A ^ n B ^ n不仅适用于A和B何时是终端，而且也适用于当A和B是任意DCG目标时。

以下是代码：

 s(_,_) --> [].
 s(A,B) --> A, s(A,B), B.

这里可以看到由SWI-Prolog完成的翻译。可以看出裸变量已被转换短语/ 3个目标：

 ?- listing.
 s(_, _, A, A).
 s(A, C, B, F) :-
    phrase(A, B, D),
    s(A, C, D, E),
    phrase(C, E, F).

这是针对终端A和B的示例运行：

 ?- phrase(s("alfa","beta"),X), atom_codes(Y,X).
 X = [],
 Y = '' ;
 X = [97, 108, 102, 97, 98, 101, 116, 97],
 Y = alfabeta ;
 X = [97, 108, 102, 97, 97, 108, 102, 97, 98|...],
 Y = alfaalfabetabeta ;
 X = [97, 108, 102, 97, 97, 108, 102, 97, 97|...],
 Y = alfaalfaalfabetabetabeta .

这是一个示例运行，对于一些DCG目标为A和B：

  bit --> "0".
  bit --> "1".

  ?- length(L,8), phrase(s(("(",bit),(bit,")")),L), atom_codes(R,L).
  L = [40, 48, 40, 48, 48, 41, 48, 41],
  R = '(0(00)0)' ;
  L = [40, 48, 40, 48, 48, 41, 49, 41],
  R = '(0(00)1)' ;
  L = [40, 48, 40, 48, 49, 41, 48, 41],
  R = '(0(01)0)' ;
  Etc..

再见

Answer 4

我认为这比那更简单：

anbn(L) :- append(As, Bs, L), maplist(ab, As, Bs).
ab(a, b).

编辑：这很容易推广到任意文字。

anbn(L) :- L = [A|_], append(As, Bs, L), maplist(ab(A), As, Bs).
ab(A, A, B) :- A \== B.

编辑：在Will Ness注意到它被窃听之后：我的意思是

anbn(L) :- append([A|As], [B|Bs], L), A \= B, maplist(ab(A, B), As, Bs).
ab(A, B, A, B).

Answer 5

anbn( [] ) :- !.
anbn( L ) :- L=[A|_], copy_half( L,L, Z,Z, A,_V). % Z is second half
copy_half( [A|B], [_,_|C], [V|D], Z, A,V) :- !, copy_half( B,C, D,Z, A,V).
copy_half( Z,     [],      [],    Z, A,V) :- A \== V.

相当于

anbn_verboten(L):- L = [] ;
  length(L,N), N2 is N div 2, length(X,N2), length(Y,N2), append(X,Y,L), 
  L=[P|_], Y=[Q|_], P \= Q.`.

在没有算术的情况下识别Prolog中的A ^ n B ^ n语言

5 个答案: