Question

我在寻找Delphi的数据库连接池实现时遇到了这个问题。

对象池需要两种方法：

get - 从池中获取一个对象（如果池为空或者其大小未达到其最大大小，这将创建一个新实例），此方法必须是线程安全的，以便一个对象不能被两个线程同时获得。如果所有对象都在使用，则get方法必须阻止（可能具有可选的超时）
put - 将对象释放（返回）到池

因此用例看起来像

O := Pool.Get;
try
  ... use O
finally
  Pool.Put(O);
end;

更新：添加了Delphi 2009标签，以便Generics.Collections和TMonitor可以成为实施的一部分

Answer 1

在Delphi-2009中，

TMonitor严重受损。它在Delphi-XE2 upd 4中发挥作用，这里的答案基于（或更新）。

此处，对象池基于线程安全的TThreadedQueue。

内置了一个用于创建池化对象的机制，具有线程安全性。从池中获取对象是线程安全的，并且在池创建时定义了超时。队列大小也在池创建时定义，其中也传递用于创建对象的回调例程。

uses
  System.Classes,Generics.Collections,System.SyncObjs,System.Diagnostics;

type
  TObjectConstructor = function : TObject;

  TMyPool = Class
  private
    FQueueSize,FAllocatedObjects : integer;
    FGetTimeOut : Integer;
    FQueue : TThreadedQueue<TObject>;
    FObjectConstructor : TObjectConstructor;
    FCS : TCriticalSection;
    function AllocateNewObject : TObject;
  public
    Constructor Create( AnObjectConstructor : TObjectConstructor;
                        QueueSize           : Integer;
                        GetTimeOut          : Integer);
    Destructor Destroy; override;
    procedure Put( const AnObject : TObject);
    function Get( var AnObject : TObject) : TWaitResult;
  End;

function TMyPool.AllocateNewObject: TObject;
begin
  FCS.Enter;
  Try
    if Assigned(FObjectConstructor) and
       (FAllocatedObjects < FQueueSize)
    then
    begin
      Inc(FAllocatedObjects);
      Result := FObjectConstructor;
    end
    else
      Result := Nil;
  Finally
    FCS.Leave;
  End;
end;

constructor TMyPool.Create( AnObjectConstructor : TObjectConstructor;
                            QueueSize           : Integer;
                            GetTimeOut          : Integer);
begin
  Inherited Create;

  FCS := TCriticalSection.Create;
  FAllocatedObjects := 0;
  FQueueSize := QueueSize;
  FObjectConstructor := AnObjectConstructor;
  FGetTimeOut := GetTimeOut;
  FQueue := TThreadedQueue<TObject>.Create(FQueueSize+1,Infinite,10);
  // Adding an extra position in queue to safely remove all items on destroy
end;

destructor TMyPool.Destroy;
var
  AQueueSize : integer;
  AnObject : TObject;
  wr : TWaitResult;
begin
  FQueue.PushItem(Nil); // Just to make sure we have an item in queue
  repeat // Free objects in queue
    AnObject := nil;
    wr := FQueue.PopItem(AQueueSize,AnObject);
    if (wr = wrSignaled) then
      AnObject.Free;
  until (AQueueSize = 0);
  FQueue.Free;
  FCS.Free;

  Inherited;
end;

function TMyPool.Get(var AnObject: TObject) : TWaitResult;
var
  sw : TStopWatch;
begin
  AnObject := nil;
  // If queue is empty, and not filled with enough objects, create a new.
  sw := TStopWatch.Create;
  repeat
    sw.Start;
    Result := FQueue.PopItem( AnObject); // Timeout = 10 ms
    if (Result = wrTimeOut) and
       (FAllocatedObjects < FQueueSize) and
       Assigned(FObjectConstructor)
    then begin  // See if a new object can be allocated
      AnObject := Self.AllocateNewObject;
      if Assigned(AnObject) then
      begin
        Result := wrSignaled;
        Exit;
      end;
    end;
    sw.Stop;
  until (Result = wrSignaled) or (sw.ElapsedMilliseconds > FGetTimeOut);
end;

procedure TMyPool.Put( const AnObject: TObject);
begin
  FQueue.PushItem(AnObject); // Put object back into queue
end;

像这样定义TObjectConstructor函数：

function MyObjectConstructor : TObject;
begin
  Result := TMyObject.Create( {Some optional parameters});
end;

以及如何使用的示例：

var
  AnObject : TObject;
  MyObject : TMyObject;
  wr : TWaitResult;
begin
  wr := MyObjPool.Get(AnObject);
  if (wr = wrSignaled) then 
  begin
    MyObject := TMyObject(AnObject);
    try
      // Do something with MyObject
    finally
      MyObjPool.Put(AnObject);
    end;
  end;
end

Answer 2

根据您在多个线程上执行任务或作业所使用的（线程）平台或体系结构，处理数据库连接的“通用”方法是使用threadvar和每个线程的数据库连接。如果你有一个线程池或线程管理器，它应该扩展为在添加线程时启动数据库连接（或在线程上运行的第一个任务上连接到数据库），并在线程被销毁时关闭数据库连接

Answer 3

Delphi中没有通用对象池。您必须自己动手，或使用第三方代码，例如在这里：delphipooling

Answer 4

今天刚刚遇到Boosting Work Classes with a mini Object Pool，由dwScript的当前 awesome 开发人员Eric。

Answer 5

Spring4D - Spring.Container.Pool.pas有一个对象池实现，我还没有尝试过，但是你知道，Delphi社区的人都知道Spring4D是高质量的：）

似乎没有文档，但它有test cases here

Delphi是否有通用的“对象池”实现？

5 个答案: