Question

我做下一个作业=）我的任务是用斐波纳契数[0,1,1,2,3,5,8 ..]创建无限列表我可以使用Prelude的任何功能。

我的尝试：

fibs2 :: [Integer]
fibs2 = reverse $ foldr f [1,0] [0..]
  where 
        f _ (x:y:xs) = (x+y):x:y:xs

此函数仅适用于[0..100]等有限列表它给出了无限的列表：

*** Exception: stack overflow

我做错了什么？如何制作“懒惰”功能？

更新我的第二次尝试：

fibs4 = 0:[ b | (a, b) <- scanl (\(x,y) _ -> (y,x + y)) (0,1) [0..] ]

它运作正常。 :) 这是正常的还是奇怪的？

Answer 1

foldr（使用严格的组合函数）将参数列表解构为其末尾，然后通过用户提供的组合函数f重新组合它：

foldr f z [a,b,c,...,y] = f a (f b (f c (.....(f y z).....)))

在你的情况下，

fibs2 = reverse $ foldr (\_ (x:y:xs) -> (x+y):x:y:xs) [1,0] [0..]

foldr这里永远不会产生任何输出。但这并不是因为缺乏尝试：它在搜索结束时非常难以递归无限列表，因为它的组合函数是 strict （它匹配foldr的其余部分在构造自己的结果之前输出(x:y:xs)。

带有严格组合函数的

Foldr表示递归，并且递归必须有其基本情况才能停止。您的想法如下：

fibs2 = reverse $ snd $ until (null.fst) 
         (\(_t:ts, x:y:xs) -> (ts, (x+y):x:y:xs)) ([0..],[1,0])

显然是非终止的。 ts只是表达了时间的流逝。我们可以尝试查看其执行的整个历史，将其重写为

fibs2 = reverse $ snd $ last $ iterate
         (\(_t:ts, x:y:xs) -> (ts, (x+y):x:y:xs)) ([0..],[1,0])

当然，无限列表中没有最后一个元素。但我们现在至少可以看到所有的中期结果：

> mapM_ (print.reverse.snd) $ take 11 $ iterate 
          (\(_:ts, x:y:xs) -> (ts, (x+y):x:y:xs)) ([0..],[1,0])
[0,1]
[0,1,1]
[0,1,1,2]
[0,1,1,2,3]
[0,1,1,2,3,5]
[0,1,1,2,3,5,8]
[0,1,1,2,3,5,8,13]
[0,1,1,2,3,5,8,13,21]
[0,1,1,2,3,5,8,13,21,34]
[0,1,1,2,3,5,8,13,21,34,55]
[0,1,1,2,3,5,8,13,21,34,55,89]

因此，不要等到最后一个列表构建（从不）和然后反转它，为什么不在我们去的时候生成它的元素？无论如何，它已经存在了。并且每个中间结果的最后一个元素是相反的 - 它不仅仅是它的第一个元素吗？

> take 11 $ map (head.snd) $ iterate 
          (\(_:ts, x:y:xs) -> (ts, (x+y):x:y:xs)) ([0..],[1,0])
[1,1,2,3,5,8,13,21,34,55,89]

干净，呵呵。那么我们需要明确的时间计数器吗？我们是否需要沿着前一个中期结果的整个尾部拖动，或者我们只需要它的前两个元素？

fibs = map (head.tail) $ iterate (\[x,y] -> [x+y,x]) [1,0]

将元组用于常量长度列表会更清晰一些。所以你看到我们来到这里的一个规范定义，

fibs = g (1,0)  where  g (a,b) = b : g (a+b,a)

（另见What's the difference between recursion and corecursion?）。

你的“第二次尝试”，

fibs4 = 0:[ b | (a, b) <- scanl (\(x,y) _ -> (y,x + y)) (0,1) [0..] ]

你可以看到

实际上与上面非常接近。时间计数列表上的scanl仅相当于iterate。所以它相当于

fibs4a = [a | (a,b) <- iterate (\(a,b) -> (b, a+b)) (0,1)]

我们在上面的推导中看到了map变体，使用了元组而不是列表。

Answer 2

是的，你无法反转无限阵列。

看看这个：

0,1,1,2,3,5,8,13,21,...
  0,1,1,2,3,5,8, 13...   +
----------------------
0,1,2,3,5,8,13,21,...

从我试图展示关系如何使用自身生成Fibonacci序列中可以看出，这很容易！你会使用加法函数zipWith斐波纳契及其尾巴！

fibs = 0 : 1 : zipWith (+) fibs (tail fibs)

稍微详细一点，以下是对上述内容的扩展。

fibs = 0 : 1 : zipWith (+) fibs (tail fibs)
fibs = 0 : 1 : zipWith (+) 0:1:? 1:?
fibs = 0 : 1 : (0+1) : zipWith (+) 1:? ?
fibs = 0 : 1 : 1 : zipWith (+) 1:1:? 1:?
fibs = 0 : 1 : 1 : 2 : zipWith (+) 1:2:? 2:?
fibs = 0 : 1 : 1 : 2 : 3 : zipWith (+) 2:3:? 3:?

ad infinitum ... ?表示thunk，这是一个尚未评估的Haskell计算。

用Fibonacci数创建无限列表

2 个答案: