Question

我正在使用Indy（idHTTP）从互联网上下载EXE文件，我可以使用memorystream或filestream将其保存到磁盘，但我真的不知道它们之间是否有任何区别（可能在结果结构中）文件？）。我找不到答案。

其中，这里有两个简单的函数来模拟我在做什么：

Function DownloadMS(FUrl, Dest: String): Boolean;
var
  Http: TIdHTTP;
  Strm: TMemoryStream;
Begin
  Result := False;
  Http := TIdHTTP.Create;
  Strm := TMemoryStream.Create;
  With Http, Strm Do
  Try
    Try
      Get(FUrl, Strm);
      If (Size > 0) Then
      Begin
        Position := 0;
        SaveToFile(Dest);
        Result := True;
      end;
    Except
    end;
  Finally
    Strm.Free;
    Http.Free;
  end;
end;

Function DownloadFS(FUrl, Dest: String): Boolean;
var
  Http: TIdHTTP;
  Strm: TFileStream;
Begin
  Result := False;
  Http := TIdHTTP.Create;
  Strm := TFileStream.Create(Dest, fmCreate);
  With Http, Strm Do
  Try
    Try
      Get(FUrl, Strm);
      Result := (Size > 0);
    Except
    end;
  Finally
    Strm.Free;
    Http.Free;
  end;
end;

您的专家考虑使用一种或其他类型（内存流或文件流）？使用一种或其他类型时，EXE文件的结构有什么不同吗？推荐什么类型？

谢谢！祝周末愉快！

Answer 1

从流的角度来看，TMemoryStream或TFileStream之间没有区别。

它们都是流并且包含字节流，并且都来自TStream。

您可以像这样实现广义的功能

function DownloadToStream( const AUrl : String; ADest : TStream ): Boolean;
var
  LHttp: TIdHTTP;
begin
  LHttp := TIdHTTP.Create;
  try
    LHttp.Get( AUrl, ADest );
    Result := ADest.Size > 0;
  finally
    LHttp.Free;
  end;
end;

并使用TFileStream

进行调用

var
  LStream : TStream;

begin
  LStream := TFileStream.Create( 'MyFile.exe', fmCreate );
  if DownloadToStream( '', LStream ) then
    ...
end;

或TMemoryStream或您喜欢的任何流实例

Answer 2

在许多情况下，在下载和文件之间放置中间内存流是没有意义的。所有这一切都是消耗内存，因为你必须先把整个文件放到内存中，然后才能把它放到磁盘上。直接使用文件流可以避免这个问题。

文件流选项出现问题的主要情况是，如果要确保在保存到磁盘之前已成功下载整个文件。例如，如果要覆盖文件的先前版本，则可能需要下载它，检查哈希签名，然后才覆盖原始文件。在这种情况下，您需要在覆盖之前将文件放到某个临时位置。您可以使用内存流，也可以使用临时文件名来使用文件流。

Delphi - MemoryStream或FileStream

2 个答案: